STAMCE

Outputting pubset attributes

The STAMCE macro provides information about the contents of the MRSCAT entries and also displays the LARGE_OBJECTS attributes.

Extract from the STAMCE DSECT

             STAMCE MF=D,PREFIX=D,XPAND=MCE,VERSION=5
:
:
2 *
2 DMCFDATT   DS    X        attribute
2 DMCFDLOB   EQU   X'40'    set: large_objects
2 *                              files/volumes with more than 32 GB
2 DMCFDLFA   EQU   X'20'    set: large_files_allowed
2 DMCFDRAI   EQU   X'10'    set: pubset with RAID volumes
2 DMCFDGSV   EQU   X'08'    set: gs volumes
2 DMCFDDRV   EQU   X'02'    set: high availability by DRV
2 DMCFDKEY   EQU   X'01'    set: key pubset
2 * 
:

Example

The output of attributes addressed with DMCFDATT is laid out in such a way that in the output columns, YES stands for “allowed/existing” and NO for “not allowed/non existent”. The LARGE_OBJECTS attributes are output in the LOB and LFA columns.

STAMCE   START
         PRINT  NOGEN
         BALR   10,0
         USING  *,10
         USING  DSTAM3,6
         USING  DSTAM4,7
         STAMCE MF=E,PARAM=STAM3,VERSION=5
         LR     7,1
         L      6,DMCEAREA
         WROUT  HEADER,WROUTERR
SHOW     MVC    ATTRIB,=C'NO  NO  NO  NO  NO  NO  '
         MVC    CATID,DMCFSCTD
         MVC    PROCESS,DMCFSBCA
TLOB     TM     DMCFDATT,DMCFDLOB
         BZ     TLFA
         MVC    LOB,YES
TLFA     TM     DMCFDATT,DMCFDLFA
         BZ     TRAI
         MVC    LFA,YES
TRAI     TM     DMCFDATT,DMCFDRAI
         BZ     TGSV
         MVC    RAI,YES
TGSV     TM     DMCFDATT,DMCFDGSV
         BZ     TDRV
         MVC    GSV,YES
TDRV     TM     DMCFDATT,DMCFDDRV
         BZ     TKEY
         MVC    DRV,YES
TKEY     TM     DMCFDATT,DMCFDKEY
         BZ     TEND
         MVC    KEY,YES
TEND     NOP    TEND
         CLI    PROCESS,X'00'
         BNE    WROUT2
         MVC    PROCESS,=CL8' '
WROUT2   WROUT  OUTREC,WROUTERR
         LA     6,DMCF#(6)
         CLI    DMCFSCTD,' '
         BNE    SHOW
WROUTERR TERM
*** DEFINITIONS 
STAM3    STAMCE CATID=' ',MF=L,VERSION=5
HEADER   DC     Y(HEADERE-HEADER)
         DC     CL2' '
         DC     CL1' '
         DC     C'CATID  PROCESSOR LOB LFA RAI GSV DRV KEY '
HEADERE  EQU    *
OUTREC   DC     Y(OUTRECE-OUTREC)
         DC     CL2' '
         DC     CL1' '
CATID    DS     CL4
         DC     CL3' '
PROCESS  DS     CL8
         DC     CL2' '
ATTRIB   DS     0CL24
LOB      DS     CL4
LFA      DS     CL4
RAI      DS     CL4
GSV      DS     CL4
DRV      DS     CL4
KEY      DS     CL4
OUTRECE  EQU    *
YES      DC     C'YES'
         LTORG
         DS     0F
OUT      DS     XL4096
DSTAM3   STAMCE MF=D,PREFIX=D,XPAND=MCE,VERSION=5
DSTAM4   STAMCE MF=D,PREFIX=D,XPAND=PL,VERSION=5
         END

Print-edited output

CATID  PROCESSOR LOB LFA RAI GSV DRV KEY 
 AARZ             NO  NO  NO  NO  NO  NO
 BAU3   KAROBUBE  NO  NO  NO  NO  NO  NO
 BLAU             NO  NO  NO  NO  NO  NO
 BXT2             YES NO  NO  NO  NO  NO
  :  
 WORK             YES YES NO  NO  NO  YES 
 2ATS   PIKASS    NO  NO  YES NO  NO  YES 
 2CVC   KAROBUBE  NO  NO  NO  NO  NO  NO
 4ARB   D015ZE08  NO  NO  NO  NO  NO  YES 
  :