Nutzung der Ausgabe in S-Variable

Diese Prozedur führt einen Abgleich zwischen zwei Bibliotheken durch:

Alle Elemente, die in der neueren Bibliothek (Prozedurparameter NEW-LIB) enthalten sind, werden in der älteren Bibliothek (Prozedurparameter OLD-LIB) gelöscht.

/BEGIN-PARAMETER-DECLARATION 
/DECLARE-PARAMETER NAME=OLD-LIB(INITIAL-VALUE=*PROMPT) 
/DECLARE-PARAMETER NAME=NEW-LIB(INITIAL-VALUE=*PROMPT) 
/END-PARAMETER-DECLARATION 
/DECLARE-VARIABLE NAME=NEW-ELEMENTS(TYPE=*STRUC), - 
/                 MULTIPLE-ELEMENTS=*LIST ----------------------------------------   (1) 
/BEGIN-BLOCK DATA-INSERTION=*YES 
/START-LMS 
//SHOW-ELEM-ATTR  - 
//       ELEM=*LIB-ELEM(LIB=&NEW-LIB,ELEM=*ALL,TYPE=*ALL),- 
//       INF=*MIN,STRUCTURE-OUTPUT=NEW-ELEMENTS ----------------------------------   (2) 
/DECLARE-VARIABLE NAME=LOOP(TYPE=*STRUC) -----------------------------------------   (3) 
/FOR LOOP=*LIST(NEW-ELEMENTS) 
//DELETE-ELEM  *LIB-ELEM(LIB=&OLD-LIB, - 
//                       ELEM=&(LOOP.ELEM)(VERS=&(LOOP.VERSION)), - 
//                       TYPE=&(LOOP.TYPE)) --------------------------------------   (4) 
//STEP   "falls Element in &OLD-LIB nicht existiert" 
/END-FOR 
//END 
/END-BLOCK 

(1)	Deklarieren der Variablen für die Ausgabe von //SHOW-ELEMENT-ATTRIBUTES.
(2)	Ausgabe von //SHOW-ELEMENT-ATTRIBUTES in die Variable.
(3)	Deklarieren der Schleifen-Variable.
(4)	Löschen der Elemente in einer Schleife; für Element, Version und Typ werden die Werte der Schleifen-Variablen benutzt.