Mit dem Aufruf CALL "NLSHOW"... können Sie sich die FTAM-Attribute einer Datei im lokalen System anzeigen lassen. Der Funktionsumfang entspricht dem Kommando SHOW-FILE-FT-ATTRIBUTES.
Für die Ausgabe der Attribute kann der Benutzer drei Varianten wählen:
Anzeige des Namens der Datei,
Anzeige einer Standardauswahl,
Anzeige aller Attribute einer Datei.
Die Ausgabe kann auf Bildschirm oder in eine Datei erfolgen.
Zusätzlich zu den von der openFT (BS2000) Kommandoschnittstelle gebotenen Möglichkeiten können die Dateinamen wahlweise auch über ihre Linknamen angegeben werden.
Aufruf
Die Funktion können Sie wie folgt aufrufen:
CALL "NLSHOW" USING FT-NLSHOW-LIST FT-RETURN-INFO.
FT-NLSHOW-LIST
Der Bereich FT-NLSHOW-LIST beschreibt die Parameterliste für den NLSHOW-Aufruf. FT-NLSHOW-LIST muss in der WORKING-STORAGE SECTION definiert sein und kann mit der Anweisung
COPY FTNLSHOW OF linkname.
dorthin kopiert werden.
Vor dem ersten NLSHOW-Aufruf sollten die Parameterfelder mit der Anweisung
MOVE LOW-VALUE TO USER-PARAMETERS IN FT-NLSHOW-LIST.
gelöscht werden.
Vor einem weiteren NLSHOW-Aufruf müssen Sie die gewünschten Felder ausfüllen. Soll ein Parameter nicht angegeben werden bzw. auf den Standardwert Bezug genommen werden, so muss diesem Feld der Wert LOW-VALUE zugewiesen werden.
FT-NLSHOW-LIST ist folgendermaßen definiert:
01 FT-NLSHOW-LIST.
*
02 FILLER PIC X(4) VALUE "V500".
*
02 USER-PARAMETERS.
*
05 FILE-NAME PIC X(54).
88 NOT-SPECIFIED VALUE LOW-VALUE.
05 LINK-NAME PIC X(8).
88 NOT-SPECIFIED VALUE LOW-VALUE.
*
05 INFORMATION PIC X(1).
88 STD VALUE LOW-VALUE.
88 ALL-ATTRIBUTES VALUE "A".
88 ONLY-NAME VALUE "O".
*
05 OUTPUT-PAR PIC X(1).
88 SYSOUT VALUE LOW-VALUE.
88 SYSLST VALUE "L".
88 SYSOUTCSV VALUE "O".
88 SYSLSTCSV VALUE "C".
Die am Anfang der Struktur stehende Versionsangabe dient zur Identifikation des COPY-Elements und darf vom Benutzer nicht überschrieben werden.
Durch einen NLSHOW-Aufruf werden keine Werte in der Struktur FT-NLSHOW-LIST geändert.
Die Felder sind linksbündig zu beschreiben und rechtsbündig mit Leerzeichen aufzufüllen (Standard bei der COBOL-MOVE-Anweisung für Zeichenketten).
Felder, die keine Angaben enthalten sollen, sind mit der Zuweisung LOW-VALUE zu kennzeichnen.
Bei Nichtangabe eines Parameters werden wie beim Kommando SHOW-FILE-FT-ATTRI-BUTES die Standardwerte abgesetzt.
Für die Zuweisung von Schlüsselworten, zum Beispiel *ONLY-NAME und *SYSLST, sind die Werte zu verwenden, die in den entsprechenden Strukturstufe-88-Erklärungen festgelegt sind.
Beschreibung der Datenfelder
Die Parameter der FT-NLSHOW-LIST haben dieselben Namen und Funktionen wie die entsprechenden Operanden des Kommandos SHOW-FILE-FT-ATTRIBUTES. Bitte beachten Sie daher die entsprechende Kommandobeschreibung im Handbuch "openFT (BS2000) - Kommandoschnittstelle".
Zusätzlich zu den an der Kommandoschnittstelle angebotenen Möglichkeiten können Sie Datei- und Bibliotheksnamen in COBOL-Programmen auch über Link-Namen ansprechen. Dazu dient das Feld LINK-NAME in der FT-NLSHOW-LIST.
Es darf jeweils entweder nur der Linkname oder der Datei- bzw. Bibliotheksname angegeben werden.
Ein zum Ablaufzeitpunkt nicht zugewiesener Linkname führt zu der Meldung
FILE UNKNOWN.
Beispiel NLSHOW
*******************************************************************
* BEISPIEL: *
* *
* /SHOW-FILE-FT-ATTRIBUTES FILE-NAME=LOCALFILE,- *
* / INFORMATION=*ALL-ATTRIBUTES *
* *
* AUS EINEM COBOL-PROGRAMM *
*******************************************************************
IDENTIFICATION DIVISION.
PROGRAM-ID. TESTNLSHOW.
*
ENVIRONMENT DIVISION.
*
CONFIGURATION SECTION.
SPECIAL-NAMES.
TERMINAL IS TERM.
*
DATA DIVISION.
WORKING-STORAGE SECTION.
77 MAIN-RCODE-STRING PIC -ZZZZ9.
77 SUB-RCODE-STRING PIC -ZZZZ9.
COPY FTNLSHOW OF FTLIB.
COPY FTRETC OF FTLIB.
*
PROCEDURE DIVISION.
STEUER SECTION.
ST-01.
*
*PARAMETER-VERSORGEN.
MOVE LOW-VALUE TO USER-PARAMETERS.
MOVE "LOCALFILE" TO FILE-NAME.
SET ALL-ATTRIBUTES IN INFORMATION TO TRUE.
*
*NLSHOW-AUFRUFEN.
CALL "NLSHOW" USING FT-NLSHOW-LIST FT-RETURN-INFO.
*
*ERGEBNIS-BEHANDLUNG.
IF OKAY IN MAIN-RETURN-CODE
THEN
DISPLAY "NLSHOW OKAY" UPON TERM
ELSE
MOVE MAIN-RETURN-CODE TO MAIN-RCODE-STRING
MOVE SUB-RETURN-CODE TO SUB-RCODE-STRING
DISPLAY "NLSHOW ABGELEHNT" UPON TERM
DISPLAY "MAIN-RETURN-CODE: " MAIN-RCODE-STRING
" SUB-RETURN-CODE: " SUB-RCODE-STRING
UPON TERM.
ST-99.
STOP RUN.