openFT V12.1C (en)

&pagelevel(4)&pagelevel

This section provides sample applications of the TRANSFER-FILE command.

TRANSFER-FILE command for openFT with mandatory operands only

When the conditions in section “The shortest form of the command” apply, the TRANSFER-FILE command can be entered only with the mandatory operands.

In the following example the file DATA is to be transferred from the local computer to the partner computer HOST001.The command is entered in the recommended short form.

/TFF TO,HOST001,(DATA)

% FTR0000 Request (&00) accepted

/

The long form of this command is as follows:

/TRANSFER-FILE TRANSFER-DIRECTION=TO, -

/ PARTNER=HOST001, -

/ LOCAL-PARAMETER=(FILE-NAME=DATA)

If the user operating under this user ID continues to operate in interactive mode, he/she receives the following asynchronous message after successful file transfer:

%MESS % FTR0005 (&01'')Request (&00). File '(&02)' transferred

Transfer of a file with password protection cataloged under another user ID in the remote system.

The file LIST is stored in computer HOST002 under the user ID SHIPPING and protected by the password C’XX’. The user ID SHIPPING has the account number SHIP002 and the password PASS1492.

The example below shows both the short form and the long form of the command used to transfer the file LIST to the local system and store it there in the file LIST.002, which has not yet been created. If this file already exists, the LIST file should not be transferred.

Recommended short form of the command:

/TRANS-FILE FROM,HOST002, -

/ (LIST.002), -

/ (LIST,'XX',TRANS-AD=(SHIPPING,SHIP002,'PASS1492')),WRITE=NEW
% FTR0000 Request (&00) accepted

Long form of the command:

/TRANSFER-FILE TRANSFER-DIRECTION=FROM-PARTNER,PARTNER=HOST002, -

/ LOCAL-PARAMETER=(FILE-NAME=LIST.002), -

/ REMOTE-PARAMETER=*BS2000(FILE-NAME=LIST,PASSWORD=C'XX', -
/ TRANSFER-ADMISSION=(USER-IDENTIFICATION=SHIPPING, -

/ ACCOUNT=SHIP002,PASSWORD='PASS1492')),WRITE-MODE=*NEW-FILE

% FTR0000 Request (&00) accepted

Collection of files

A central office has to collect the monthly reports from its 5 branch offices on the first of every month. These monthly reports are edited ready for printing in each of the branch offices and contained in a file called REPORT.month and are each to be transferred into a file in the central location called REPORT.month.branch-office and printed out there. For retrieval of the data, the transfer admission GETREPORT has been set up on each branch computer.

The transfer of these files is carried out with the following procedure:

/BEGIN-PROCEDURE LOGGING=NO,PARAMETERS=YES(PROCEDURE-PARAMETERS= -

/(&MONTH=),ESCAPE-CHARACTER='&')

/REMARK PLEASE SPECIFY THE PREVIOUS MONTH FOR &MONTH !

/TRANS-FILE FROM,BRANCH1, -

/(REPORT.&MONTH..BRANCH1, -

/SUCC='/PRINT-FILE FILE-NAME=REPORT.&MONTH..BRANCH1, -
/SPOOLOUT-NAME=BRANCH1,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)'), -

/(REPORT.&MONTH,TRANS-AD=GETREPORT)

/TRANS-FILE FROM,BRANCH2, -

/(REPORT.&MONTH..BRANCH2, -
/SUCC='/PRINT-FILE FILE-NAME=REPORT.&MONTH..BRANCH2, -

/SPOOLOUT-NAME=BRANCH2,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)'), -

/(REPORT.&MONTH,TRANS-AD=GETREPORT)

/TRANS-FILE FROM,BRANCH3, -

/(REPORT.&MONTH..BRANCH3, -

/SUCC='/PRINT-FILE FILE-NAME=REPORT.&MONTH..BRANCH3, -
/SPOOLOUT-NAME=BRANCH3,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)'), -

/(REPORT.&MONTH,TRANS-AD=GETREPORT)

/TRANS-FILE FROM,BRANCH4, -
/(REPORT.&MONTH..BRANCH4, -

/SUCC='/PRINT-FILE FILE-NAME=REPORT.&MONTH..BRANCH4, -

/SPOOLOUT-NAME=BRANCH4,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)'), -
/(REPORT.&MONTH,TRANS-AD=GETREPORT)

/TRANS-FILE FROM,BRANCH5, -

/(REPORT.&MONTH..BRANCH5, -
/SUCC='/PRINT-FILE FILE-NAME=REPORT.&MONTH..BRANCH5, -

/SPOOLOUT-NAME=BRANCH5,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)'), -

/(REPORT.&MONTH,TRANS-AD=GETREPORT)

/END-PROCEDURE

This call procedure (name: DO.MONTH) is called as follows:

/CALL-PROCEDURE DO.MONTH

%/REMARK PLEASE SPECIFY THE PREVIOUS MONTH FOR &MONTH !

%&MONTH=november

% FTR0000 Request 194577 accepted

% FTR0000 Request 194987 accepted

% FTR0000 Request 195442 accepted
% FTR0000 Request 196099 accepted

% FTR0000 Request 196583 accepted

/

Distribution of files

A central office distributes guidelines to its five branch offices. It has the guidelines printed out as soon as they are received in the branch. All user IDs concerned in the central office and in the branch offices are CENTRAL, have the account number CENTR01 and the password C’CEN’.

To distribute the guidelines the central office uses the following ENTER-JOB procedure:

/LOGON

/TRANS-FILE TO,BRANCH1, -

/(GUIDELINE,TRANS-AD=(CENTRAL,CENTR01,C'CEN')), -
/(SUCC='/PRINT-FILE FILE-NAME=GUIDELINE,SPOOLOUT-NAME=IMPORTNT, -

/LAYOUT-CONTROL=(CONTROL-CHARACTER=EBCDIC)')

/TRANS-FILE TO,BRANCH2, -
/(GUIDELINE,TRANS-AD=(CENTRAL,CENTR01,C'CEN')), -

/(SUCC='/PRINT-FILE FILE-NAME=GUIDELINE,SPOOLOUT-NAME=IMPORTNT, -

/LAYOUT-CONTROL=(CONTROL-CHARACTER=EBCDIC)')

/TRANS-FILE TO,BRANCH3, -

/(GUIDELINE,TRANS-AD=(CENTRAL,CENTR01,C'CEN')), -

/(SUCC='/PRINT-FILE FILE-NAME=GUIDELINE,SPOOLOUT-NAME=IMPORTNT, -
/LAYOUT-CONTROL=(CONTROL-CHARACTER=EBCDIC)')

/TRANS-FILE TO,BRANCH4, -

/(FILE=GUIDELINE,TRANS-AD=(CENTRAL,CENTR01,C'CEN')), -
/(SUCC='/PRINT-FILE FILE-NAME=GUIDELINE,SPOOLOUT-NAME=IMPORTNT, -

/LAYOUT-CONTROL=(CONTROL-CHARACTER=EBCDIC)')

/TRANS-FILE TRANS=TO,PARTNER=BRANCH5, -
/(GUIDELINE,TRANS-AD=(CENTRAL,CENTR01,C'CEN')), -

/(SUCC='/PRINT-FILE FILE-NAME=GUIDELINE,SPOOLOUT-NAME=IMPORTNT, -

/LAYOUT-CONTROL=(CONTROL-CHARACTER=EBCDIC)')

/LOGOFF

This ENTER-JOB procedure (name: ENTER.GUIDELINE) is called as follows:

/.CENTRAL ENTER-JOB ENTER.GUIDELINE,TIME=99

% JMS0066 JOB ACCEPTED. TSN=2083

The BS2000 command SHOW-USER-STATUS can be used to trace the sequence of this ENTER process and the file transfer operations:

/SHOW-USER-STATUS

NAME TSN TYPE PRI CPU-USED CPU-MAX ACCOUNT#

CENTRAL 2083 1 210 0.0 99 CENTR01
GP46518 2065 3 DIA 210 0.4595 32767 CENTR01

/SHOW-USER-STATUS

NAME TSN TYPE PRI CPU-USED CPU-MAX ACCOUNT#
OPENFT 2088 1 210 0.0 1 CENTR01

GP46518 2065 3 DIA 210 0.6868 32767 CENTR01

NAME TSN TYPE PRI SIZE COPIES CPU-USED
CENTRAL 2083 4 PR 210 2 0

/SHOW-USER-STATUS

NAME TSN TYPE PRI CPU-USED CPU-MAX ACCOUNT#
GP46518 2065 3 DIA 210 0.7957 32767 CENTR01

OPENFT 2099 2 BAT 210 0.0938 1 CENTR01

OPENFT 2100 2 BAT 210 0.0548 1 CENTR01
NAME TSN TYPE PRI SIZE COPIES CPU-USED

CENTRAL 2083 4 PR 210 2 0

OPENFT 2091 4 PR 210 1 0

OPENFT 2096 4 PR 210 1 0
OPENFT 2097 4 PR 210 1 0

/SHOW-USER-STATUS

NAME TSN TYPE PRI CPU-USED CPU-MAX ACCOUNT#
GP46518 2065 3 DIA 210 0.8545 32767 CENTR01

NAME TSN TYPE PRI SIZE COPIES CPU-USED

CENTRAL 2083 4 PR 210 2 0
OPENFT 2091 4 PR 210 1 0

OPENFT 2096 4 PR 210 1 0

OPENFT 2097 4 PR 210 1 0
OPENFT 2101 4 PR 210 1 0

OPENFT 2102 4 PR 210 1 0

Job transfer and job processing

To reduce the load on the central office host computer an ASSEMBLER program is to be compiled in the host computer of a branch office. To do this, the program is compiled within a CALL-PROCEDURE procedure file that is started as a follow-up processing operation. After processing of the FT request has been completed, the compiled program is stored in a module library. The module library is then to be transferred back to the central host computer.

The CALL-PROCEDURE procedure DO.JOB could look as follows:

/BEGIN-PROCEDURE LOGGING=COMMANDS

/DELETE-FILE FILE-NAME=*

/ASSIGN-SYSDTA TO-FILE=*SYSCMD

/START-ASSEMBH

.

. Program to be compiled!
.

/START-LMS

//OPEN-LIB CENTRAL.MODLIB,MODE=*UPDATE

//ADD-ELEMENT FROM-FILE=*OMF,TO-ELEMENT=*LIB-ELEM(TYPE=R)

//END

/ASSIGN-SYSDTA TO-FILE=*PRIMARY

/TRANS-FILE TRANS=TO,PARTNER=CENTRAL,LOC=(FILE-NAME=CENTRAL.MODLIB, -
/ TRANS-AD=(CENTRAL,CENTR01,C'CEN'))

/END-PROCEDURE

This CALL-PROCEDURE procedure is transferred to the computer in branch office 1 using the following command and started there. The request is to be monitored in the central host by job variable XYZ.

/TRANS-FILE TO,BRANCH1,(DO.JOB,MONJV=XYZ)REM=, -
/ (TRANS-AD=(CENTRAL,CENTR01,C'CEN'),SUCC='/CALL-PROCEDURE DO.JOB')

% FTR0000 Request 194572 accepted

Chaining of files

A central office collects SAM files (e.g. transaction files) from its 3 branch offices. The files are to be concatenated and are not to be processed until all the files to be collected have been transferred. The files have the name SAM.FILE in the example and are to be stored consecutively in the file SAM.ALL. The files to be collected are password-protected. The user IDs are not passwordprotected (The operating system BS2000 has been generated with system parameter SSMCOPT=Y.

The files are transferred using the following CALL-PROCEDURE procedure (name: DO.CHAIN):

/BEGIN-PROCEDURE LOGGING=COMMANDS

/TRANS-FILE TRANS=FROM,PARTNER=BRANCH1,WRITE=EXT, -

/REM=(FILE-NAME=SAM.FILE,PASS='FIL1',TRANS=GETFILES), -
/LOC=(FILE-NAME=SAM.ALL, -

/SUCC='/TRANS-FILE TRANS=FROM,PARTNER=BRANCH2,WRITE=EXT, -

/REM=(FILE-NAME=SAM.FILE,PASS=''FIL2'',TRANS=GETFILES), -
/LOC=(FILE-NAME=SAM.ALL, -

/SUCC=''/TRANS-FILE TRANS=FROM,PARTNER=BRANCH3,WRITE=EXT, -

/LOC=(FILE-NAME=SAM.ALL), -

/REM=(FILE-NAME=SAM.FILE,PASS=''''FIL3'''',TRANS=GETFILES)'')')

/END-PROCEDURE

The procedure is called as follows:

/CALL-PROCEDURE DO.CHAIN

%/BEGIN-PROCEDURE LOGGING=COMMANDS

%/TRANS-FILE TRANS=FROM,PARTNER=BRANCH1,WRITE=EXT,

REM=(FILE-NAME=SAM.FILE,PASS='FIL1',TRANS=GETFILES),

LOC=(FILE-NAME=SAM.ALL,SUCC='/TRANS-FILE TRANS=FROM,

PARTNER=BRANCH2,WRITE=EXT,REM=(FILE-NAME=SAM.FILE,

PASS=''FIL2'',TRANS=GETFILES),

LOC=(FILE-NAME=SAM.ALL),

SUCC=''/TRANS-FILE TRANS=FROM,PARTNER=BRANCH3,WRITE=EXT,

LOC=(FILE-NAME=SAM.ALL),

REM=(FILE-NAME=SAM.FILE,PASS=''''FIL3'''',TRANS=GETFILES)'')')

% FTR0000 Request 164572 accepted

%/END-PROCEDURE

File transfer between openFT (BS2000) and another FT system

The file FILE is to be transferred to another system using openFT(BS2000). In the other system (SYS) the user ID BROOKLYN with the password 20000 is to be used. The file is to be given the name f/i/l/e in this system. The short form of the command is used:

/TRANS-FILE TO,SYS,(FILE), -
/*ANY('f/i/l/e',TRANS-AD=('BROOKLYN',,'20000'))

% FTR0000 Request 165572 accepted

Transfer of POSIX files between two openFT (BS2000) systems

The POSIX file named ‘file’ is to be transferred to the home directory /home/JIMMY in the BS2000 computer HOST12 using openFT. The user ID JIMMY with the account number 12345678 and password 20000 are used in HOST12. As the user ID for the remote system is specified, it would have been sufficient to specify the relative path name. The short form of the command is used:

/TRANS-FILE TO,HOST12,(‘‚/file‘), -

/(c‘/home/JIMMY/file‘,TRANS-ADM=(JIMMY,12345678,'20000'))

% FTR0000 Request 165581 accepted

Command with *POSIX:

/TRANS-FILE TO,HOST12,(*POSIX(file)), --

/(*POS(/home/JIMMY/file),TRANS-ADM=(JIMMY,12345678,'20000'))

% FTR0000 Request 165581 accepted

File transfer to z/OS systems

The file FILE is to be transferred from a BS2000 computer to the z/OS computer IBM1. The file is held in the local system under the user ID CENTRBS2 and has the password C’ZZZZ’. The user ID has the account number CENTR01 and is protected by the password C’CEN1’. The file is to be called FILE in the z/OS computer, have the password FILE01, and be stored under the user ID CENMSP with the account number CENTRAL02 and password CEN2. The command is entered in the short form.

/TRANS-FILE TO,IBM1, -

/(FILE,C'ZZZZ',TRANS-AD=(CENTRBS2,CENTR01,C'CEN1')), -

/*MSP(FILE,FILE01,TRANS-AD=(CENMSP,CENTRAL02,CEN2))

% FTR0000 Request 143581 accepted

File transfer using openFT (Unix systems)

The file mailbag is to be obtained from the Unix system ALFRED and transferred to the local BS2000 system. The file is held by ALFRED under the user ID „flyte“ with a password of 144002 and is to be given the name NOHURRY in the local system. An abbreviated command for this request is as follows:

/TRANS-FILE FROM,ALFRED,(NOHURRY),*ANY('mailbag', -

/TRANS-AD=('flyte',,'144002'))

% FTR0000 Request 122181 accepted

File transfer with subsequent follow-up processing, but with no report on the execution

of the follow-up processing

The file COBOL.LIST is to be transferred from the computer with the name COMPILER to the local system and printed out there four times. This file is stored in the COMPILER computer under the user ID COBOL with account number COBACC and the password PASSWORD. The report on the execution of the print process is to be suppressed if the operation is successful. There are two ways of carrying out these operations. In the first, more detailed method a procedure FT.PRINT.PROC is initially set up in the local system containing the following:

/BEGIN-PROCEDURE LOGGING=NO,PARAMETERS=YES(PROCEDURE-PARAMETERS= -

/(&FILE=,&.COPIES=0)

/PRINT-FILE FILE-NAME=&FILE,REPEAT=&COPIES, -
/LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)

/END-PROCEDURE

The actual file transfer request has the format

/TRANS-FILE FROM,COMPILER, -
/ (COBOL.LIST, -

/ SUCC='/CALL-PROC FT.PRINT.PROC, -

/ (FILE=COBOL.LIST,COPIES=3)'), -

/ (TRANS-AD=(COBOL,COBACC,'PASSWORD’))

However, the CALL-PROCEDURE procedure is not required if a command is specified in the TRANS-FILE command for the follow-up processing. The file transfer request then has the following format:

/TRANS-FILE FROM,COMPILER, -

/ (COBOL.LIST,SUCC='/PRINT-FILE FILE-NAME=%FILENAME, -

/ REPEAT=3,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)’), -
/ (TRANS-AD=(COBOL,COBACC,'PASSWORD’))

Procedure file transfer with subsequent execution of the procedure as follow-up

processing and finally deletion of the transferred file

The procedure file PROC.JOB, which is constructed in exactly the same way as the file DO.JOB in example 5, is to be transferred to the computer BRANCH1 and executed there under the user ID CENTRAL with the account number CENTR01 and the password CEN. Then the file is to be deleted in the remote system.

The requisite command is as follows:

/TRANSFER-FILE -

/ TRANSFER-DIRECTION=TO, -

/ PARTNER=BRANCH1, -
/ LOCAL-PARAMETER=(FILE-NAME=PROC.JOB), -

/ REMOTE-PARAMETER=(TRANSFER-ADMISSION=(CENTRAL,CENTR01, -

/ 'CEN'),SUCCESS-PROCESSING='/CALL-PROCEDURE %FILENAME; -
/ /DELETE-FILE %FILENAME')

A possible short form of this command would be:

/TRANS-FILE TO,BRANCH1,(PROC.JOB),(TRANS-AD=(CENTRAL,CENTR01,'CEN'),-

/SUCC='/CALL-PROC %FILENAME;/DEL-FILE %FILENAME')

File transfer using FTAC

The file TURNOVER is to be transferred to the computer JACKJOHN. On this computer openFT (BS2000) is installed along with FTAC functionality for enhanced data protection and access control. An FT profile is provided in the computer JACKJOHN for the file transfer request.

In order to be able to work with this FT profile, the TRANSFER-ADMISSION ‘Fordearsteven’ must be specified as transfer admission for the computer JACKJOHN. Specifying this gives direct access to the FT profile in the computer JACKJOHN. This FT profile contains the predetermined name that the file is to receive in the computer JACKJOHN and the predetermined details concerning follow-up processing (SUCCESS-PROCESSING and FAILURE-PROCESSING) in this computer. The value *SAME is defined for the PROCESSING-ADMISSION.

The file transfer request must therefore contain the value *NOT-SPECIFIED for the file name.
The specification *NONE that is required for SUCCESS-PROCESSING and FAILURE-PROCESSING in this example also corresponds to the default value and can therefore be omitted. The default value *SAME for PROCESSING-ADMISSION is accepted by FTAC even if it is prespecified in the admission profile and can therefore also be omitted.

The long form of the command for the file transfer is thus as follows:

/TRANSFER-FILE -

/ TRANSFER-DIRECTION=TO, -

/ PARTNER=JACKJOHN, -
/ LOCAL-PARAMETER=(FILE-NAME=TURNOVER), -

/ REMOTE-PARAMETER=*BS2000(FILE-NAME=*NOT-SPECIFIED, -

/ TRANSFER-ADMISSION='Fordearsteven')

There is of course a short form:

/TFF TO,JACKJOHN,(TURNOVER),(*NOT-SPEC, -

/ TRANS-AD='Fordearsteven')

Time-driven file transfer

A user from the West End,
was really at his wits’ end.
He wanted his FTto be at ten fifty
and so this command he did send:

/TRANSFER-FILE TO,WESTEND2,(FILE),START=(,10:50)

/ TRANS-ADMISSION='GreetingsFromWestEnd'

With this command the file FILE is transferred to computer WESTEND2 and stored there under the same name with the same ID as in the local system. The start time for this request is set at the earliest for 10:50 on the day the request is issued. This is why there is a comma first in the parentheses after START. It indicates that for the DATE operand that should come first in the parentheses, the default value *TODAY has been taken.

Since the ID is password-protected, it is necessary to specify the transfer admission GreetingsFromWestEnd. If the IDs are not password-protected then this operand is omitted from the command.

Local file processing between two openFT (

BS2000) systems

A list of the names of files for the local ID is to be transferred to the remote file SFA-FILE.LOCAL.

/TRANSFER-FILE -

/ TRANSFER-DIRECTION=*TO-PARTNER, PARTNER=BS2PART, -

/ LOCAL-PARAMETER=(FILE-NAME= -
/ C‘|/SHOW-FILE-ATTRIBUTES OUT=*SYSLST‘), -

/ REMOTE-PARAMETER=*BS2000(FILE-NAME=SFA-FILE.LOCAL, -

/ TRANSFER-ADMISSION=PROFBS2PART)
% FTR0000 Request 172281 accepted

Short form:

/TFF TO,BS2PART,('|/SHOW-FI-ATTR OUT=*SYSLST'), -

/ (SFA-FILE.LOCAL,,PROFBS2PART)

Remote preprocessing between two openFT (

BS2000) systems

A list of the FT partner systems in the remote system is to be transferred to the local file INFO.BS2PART.

In openFT versions <10 the remote ID must possess the FT ADMINISTRATION privilege in order to be able to obtain information about the partner systems. If this is not the case then the request is aborted with message FTR2140.

/TRANSFER-FILE -
/ TRANSFER-DIRECTION=*FROM-PARTNER, PARTNER=BS2PART, -

/ LOCAL-PARAMETER=(FILE-NAME=INFO.BS2PART), -

/ REMOTE-PARAMETER=*BS2000(FILE-NAME= -
/ C‘|/SH-FT-PART OUT=*SYSLST‘, -

/ TRANSFER-ADMISSION=PROFBS2PART)

% FTR0000 Request 132281 accepted

Short form:

/TFF FROM,BS2PART,(INFO.BS2PART), -

/ ('|/SH-FT-PART OUT=*SYSLST' -

/ ,,PROFBS2PART)

FTINFO command for remote preprocessing

You want to determine what openFT version is installed on a remote computer.

/TRANSFER-FILE -

/ TRANSFER-DIRECTION=*FROM-PARTNER, PARTNER=UNKNOWN, -

/ LOCAL-PARAMETER=(FILE-NAME=FTINFO.UNKNOWN), -
/ REMOTE-PARAMETER=*BS2000(FILE-NAME= -

/ C‘|ftinfo -csv‘, -

/ TRANSFER-ADMISSION=PROFUNKNOWN)
% FTR0000 Request 132274 accepted

Short form:

/TFF FR,UNKNOWN,(FTINFO.UNKNOWN),('|ftinfo -csv',,PROFUNKNOWN)

Local preprocessing and remote postprocessing

Information on the last 100 locally written logging records should be stored in the remote BS2000 system PARTBS2, in the file FILE.LOG under the transfer admission TRANSADM. The FILE.LOG file should be write-protected after the transfer.

/TFF TO,PARTBS2,('|/SH-FT-LOG ,100,OUT=*SYSLST'),              -

/     ('|/CPF %TEMPFILE,FILE.LOG;/MDFA FILE.LOG,PROT=(,*READ)' -
/     ,,TRANSADM)

Your Browser is not longer supported

Please use Google Chrome, Mozilla Firefox or Microsoft Edge to view the page correctly

Examples of the TRANSFER-FILE command