The three disk files FILE.01, FILE.02 and FILE.03 are to be saved to tape. Since they do not all fit on a single tape, two output volumes are readied.
The two volumes are declared as a tape set. This serves to avoid multiple mounting and positioning of the save volumes.
/CREATE-TAPE-SET TAPE-SET-NAME=SET1,VOLUME=(FK0183,FK0238) &*————————— (1)
/CREATE-FILE FILE-NAME=FILE.01.TAPE,- &*—————————————————————————————— (2)
/ SUPPORT=*TAPE(VOLUME=*NO,DEVICE-TYPE=TAPE-C4)
/ADD-FILE-LINK LINK-NAME=PCOUT1,FILE-NAME=FILE.01.TAPE,-
/ ACCESS-METHOD=*SAM,-
/ SUPPORT=*TAPE(-
/ VOLUME-LIST=*TAPE-SET(TAPE-SET-NAME=SET1),-
/ FILE-SEQUENCE=1)
/CREATE-FILE FILE-NAME=FILE.02.TAPE,- &*—————————————————————————————— (3)
/ SUPPORT=*TAPE(VOLUME=*NO,DEVICE-TYPE=TAPE-C4)
/ADD-FILE-LINK LINK-NAME=PCOUT2,FILE-NAME=FILE.02.TAPE,-
/ ACCESS-METHOD=*SAM,-
/ SUPPORT=*TAPE(-
/ VOLUME-LIST=*TAPE-SET(TAPE-SET-NAME=SET1),-
/ FILE-SEQUENCE=*NEW)
/CREATE-FILE FILE-NAME=FILE.03.TAPE,-
/ SUPPORT=*TAPE(VOLUME=*NO,DEVICE-TYPE=TAPE-C4)
/ADD-FILE-LINK LINK-NAME=PCOUT3,FILE-NAME=FILE.03.TAPE,-
/ ACCESS-METHOD=*SAM,-
/ SUPPORT=*TAPE(-
/ VOLUME-LIST=*TAPE-SET(TAPE-SET-NAME=SET1),-
/ FILE-SEQUENCE=*NEW)
/START-PERCON &*—————————————————————————————————————————————————————— (4)
% PER0000 PERCON STARTED, VERSION V03.0A00
//ASSIGN-INPUT-FILE FILE=*DISK-FILE(NAME=FILE.01) &*—————————————————— (5)
//ASSIGN-OUTPUT-FILE FILE=*TAPE-FILE,LINK-NAME=PCOUT1 &*—————————————— (6)
//START-CONVERSION &*————————————————————————————————————————————————— (7)
% DMS0DE3 TAPE WITH VSN 'FK0183' FOR FILE ':2OS6:$WKST.FILE.01.TAPE'
IS MOUNTED ON DEVICE 'O1'
% DMS0DE7 SAM FILE CLOSED: FILE NAME=:2OS6:$WKST.FILE.01.TAPE,
LINK NAME=PCOUT1, BLOCK COUNT=0000000010
% PER0030 NUMBER OF PROCESSED RECORDS FOR LINK='PCIN'
(FILE=:2OS6:$WKST.FILE.01): 10
% PER0030 NUMBER OF PROCESSED RECORDS FOR LINK='PCOUT1'
(FILE=:2OS6:$WKST.FILE.01.TAPE): 10
//ASSIGN-INPUT-FILE FILE=*DISK-FILE(NAME=FILE.02) &*—————————————————— (8)
//ASSIGN-OUTPUT-FILE FILE=*TAPE-FILE,LINK-NAME=PCOUT2 &*—————————————— (9)
//START-CONVERSION &*—————————————————————————————————————————————————— (10)
% DMS0DE3 TAPE WITH VSN 'FK0183' FOR FILE ':2OS6:$WKST.FILE.02.TAPE'
IS MOUNTED ON DEVICE 'O1'
% DMS0DE3 TAPE WITH VSN 'FK0238' FOR FILE ':2OS6:$WKST.FILE.02.TAPE'
IS MOUNTED ON DEVICE 'O1' &*———————————————————————————————— (11)
% DMS0DE8 END OF TAPE FOR FILE ':2OS6:$WKST.FILE.02.TAPE' WITH LINK
NAME 'PCOUT2', BLOCK COUNT '000020' ON VOLUME WITH VSN 'TAPEKA
% DMS0DE8 END OF TAPE FOR FILE ':2OS6:$WKST.FILE.02.TAPE' WITH LINK
NAME 'PCOUT2', BLOCK COUNT '000040' ON VOLUME WITH VSN 'BD0150'
% DMS0DE7 SAM FILE CLOSED: FILE NAME=:2OS6:$WKST.FILE.02.TAPE, LINK
NAME=PCOUT2, BLOCK COUNT=0000000060
% PER0030 NUMBER OF PROCESSED RECORDS FOR LINK='PCIN'
(FILE=:2OS6:$WKST.FILE.02): 60
% PER0030 NUMBER OF PROCESSED RECORDS FOR LINK='PCOUT2'
(FILE=:2OS6:$WKST.FILE.02.TAPE): 60
/
//ASSIGN-INPUT-FILE FILE=*DISK-FILE(NAME=FILE.03) &*—————————————————— (12)
//ASSIGN-OUTPUT-FILE FILE=*TAPE-FILE,LINK-NAME=PCOUT3 &*—————————————— (13)
//END &*—————————————————————————————————————————————————————————————— (14)
% DMS0DE3 TAPE WITH VSN 'FK0183' FOR FILE ':2OS6:$WKST.FILE.03.TAPE'
IS MOUNTED ON DEVICE 'O1'
% DMS0DE7 SAM FILE CLOSED: FILE NAME=:2OS6:$WKST.FILE.03.TAPE,
LINK NAME=PCOUT3 , BLOCK COUNT=0000000010
% PER0030 NUMBER OF PROCESSED RECORDS FOR LINK='PCIN'
(FILE=:2OS6:$WKST.FILE.03): 10
% PER0030 NUMBER OF PROCESSED RECORDS FOR LINK='PCOUT3'
(FILE=:2OS6:$WKST.FILE.03.TAPE): 10
% PER0031 PERCON TERMINATED NORMALLY
/DELETE-TAPE-SET TAPE-SET-NAME=SET1 &*———————————————————————————————— (15)
(1) | The two volumes (TAPEKA and BD0150) are declared as a tape set. |
(2) | The commands CREATE-FILE and ADD-FILE-LINK define the first output file (FILE-SEQUENCE=1) to be written to tape. The two volumes are assigned via the TAPE-SET-NAME parameter. |
(3) | Further output files (FILE-SEQUENCE=*NEW) are defined in the same manner as (2). |
(4) | PERCON is started. |
(5) | The first input file is assigned. |
(6) | The first output file is assigned. |
(7) | Transfer is started. The complete input file fits on the first tape. |
(8) | Another input file is assigned. |
(9) | Another output file is assigned. |
(10) | Transfer is started. |
(11) | The input file does not fit completely on the first tape. The second tape is used for the remainder of the input file. |
(12) | Another input file is assigned. |
(13) | Another output file is assigned. |
(14) | Transfer is started. The complete input file fits on the second tape. Transfer is completed and PERCON is terminated. |
(15) | The tape set declaration is deleted. |
Loading a file from a MF/MV set
The file FILE.02.TAPE, which was saved to two tapes, is to be loaded.
/DELETE-FILE FILE-NAME=FILE.02.TAPE,SUPPRESS-ERR=DMS0533 &*——————————— (1)
/IMPORT-FILE SUPPORT=*TAPE(FILE-NAME=FILE.02.TAPE,- &*———————————————— (2)
/ VOLUME=(&volume1,&volume2),DEVICE-TYPE=TAPE-C4)
/ADD-FILE-LINK LINK-NAME=PCIN,FILE-NAME=FILE.02.TAPE,- &*————————————— (3)
/ SUPPORT=*TAPE(FILE-SEQUENCE=*UNKNOWN)
/CREATE-FILE FILE-NAME=FILE.02
/ADD-FILE-LINK LINK-NAME=PCOUT,FILE-NAME=FILE.02,- &*————————————————— (4)
/ ACCESS-METHOD=*SAM,-
/ RECORD-FORMAT=*FIXED,RECORD-SIZE=2000
/START-PERCON &*——————————————————————————————————————————————————————— (5)
% PER0000 PERCON STARTED, VERSION V03.0A00
//ASSIGN-INPUT-FILE FILE=*TAPE-FILE &*————————————————————————————————— (6)
//END &*——————————————————————————————————————————————————————————————— (7)
% DMS0DE3 TAPE WITH VSN 'FK0183' FOR FILE ':2OS6:$WKST.FILE.02.TAPE'
IS MOUNTED ON DEVICE 'O2'
% DMS0DE3 TAPE WITH VSN 'FK0238' FOR FILE ':2OS6:$WKST.FILE.02.TAPE'
IS MOUNTED ON DEVICE 'O3'
% DMS0DE8 END OF TAPE FOR FILE ':2OS6:$WKST.FILE.02.TAPE' WITH LINK
NAME 'PCIN', BLOCK COUNT '000020' ON VOLUME WITH VSN 'FK0183'
% DMS0DE8 END OF TAPE FOR FILE ':2OS6:$WKST.02.TAPE' WITH LINK
NAME 'PCIN', BLOCK COUNT '000040' ON VOLUME WITH VSN 'FK0238'
% DMS0DE7 SAM FILE CLOSED: FILE NAME=:2OS6:$WKST.FILE.02.TAPE, LINK
NAME=PCIN, BLOCK COUNT=0000000060
% PER0030 NUMBER OF PROCESSED RECORDS FOR LINK='PCIN'
(FILE=:2OS6:$WKST.FILE.02.TAPE): 60
% PER0030 NUMBER OF PROCESSED RECORDS FOR LINK='PCOUT'
(FILE=:2OS6:$WKST.FILE.02): 60
% PER0031 PERCON TERMINATED NORMALLY
(1) | The catalog entry, if any, for the file to be loaded is deleted. |
(2) | The file to be loaded is imported from the volumes of the MF/MV set. |
(3) | The input file is assigned using the ADD-FILE-LINK command. The parameter FILE-SEQUENCE=*UNKNOWN is specified since the position of the input file in the sequence of files contained on the volumes is not known. |
(4) | An output file is assigned on disk. |
(5) | PERCON is started. |
(6) | The input file is assigned: Assigning the input file with ASSIGN-INPUT-FILE is necessary as FILE=*TAPE-FILE is not the default value.The ASSIGN-OUTPUT-FILE statement can be omitted since the output file is defined unequivocally by the ADD-FILE-LINK command and the default settings of the ASSIGN statement. |
(7) | Transfer is started. The input file is loaded from two volumes and PERCON is terminated. |