Die Aufbereitung der SATLOG-Dateien ist Aufgabe der SAT-Datei-Verwaltung oder der SAT-Datei-Auswertung. Für die Aufbereitung steht das Dienstprogramm SATUT unter der Kennung SYSAUDIT zur Verfügung.
Es ist unabhängig vom SAT-Subsystem SATCP unter jeder Benutzerkennung ablauffähig, die das Privileg SAT-FILE-MANAGEMENT oder SAT-FILE-EVALUATION besitzt.
SATUT kann neben SATLOG-Dateien auch CONSLOG-Dateien (siehe "Tabellen der protokollierbaren Information je Objektereignis (1)") in die Auswertung einbeziehen.
Der SAT-Auswerter SATUT dient dazu,
aus den Eingabedateien aufbereitete Dateien (replacement-files) zu erstellen, in denen die sicherheitsrelevanten Aufzeichnungen stehen, die die SAT-Datei-Verwaltung oder SAT-Datei-Auswertung ausgewählt hat. In diesem Fall ist das Ziel die Reduktion der Datenmenge und Aufbewahrung der sicherheitsrelevanten SATLOG-Sätze, d.h. die Eingabedateien können durch die aufbereiteten Dateien ersetzt werden.
aus den Eingabedateien mit Auswahlbedingungen bestimmte Protokolldatensätze auszuwählen. Diese werden auf Drucker (SYSLST) oder in eine XML-Datei ausgegeben, statistisch dargestellt oder in eine Datei (analysis-file) geschrieben. In diesem Fall ist das Ziel die Analyse ausgewählter Ereignisgruppen, d.h. die Eingabedateien werden nicht durch die aufbereiteten Dateien ersetzt.
Um Speicherplatz für SATLOG-Dateien einzusparen, sollten diese regelmäßig gewechselt (Kommando CHANGE-SAT-FILE), so bald wie möglich aufbereitet und durch replacementfiles ersetzt oder auf Datenträger für langfristige Archivierung ausgelagert werden. Mit der Aufbereitung wird der Umfang der protokollierten Daten durch die feinere Auswahlmöglichkeit von SATUT reduziert.
Im folgenden Beispiel wird ein Batch-Job dargestellt, der unter der Benutzerkennung SYSAUDIT erstellt wurde und einmal pro Tag abläuft . In diesem Job wird ein Job erstellt, der alle SATLOG-Dateien und replacement-files des Vortages ausgewertet, sofern ihr Name eine vierstellige Jahresangabe enthält. Das Ergebnis wird in einer einzigen analysis-file gespeichert. Danach werden die als Eingabe verwendeten SATLOG-Dateien automatisch gelöscht, replacement-files hingegen bleiben erhalten.
Um unbefugten Zugriff auf ausgedruckte Ausgabe-Protokolle zu verhindern, wird die Ausgabe, die auf die Systemdatei SYSLST erfolgt, in eine katalogisierte Datei umgelenkt. Diese kann z.B. mit SHOW-FILE auf dem Bildschirm untersucht werden.
/SET-LOGON-PARAMETERS
/REMARK *------------------------------------------------------------*
/REMARK * DIESER BATCH-JOB WERTET SATLOG-DATEIEN UND REPLACEMENT- *
/REMARK * FILES ANHAND DES DATUMS AUS. NUR DIE DATEIEN MIT DEM *
/REMARK * AELTESTEN DATUM WERDEN BEHANDELT. FUER DATEIEN DES *
/REMARK * AKTUELLEN TAGES FINDET KEINE AUSWERTUNG STATT. *
/REMARK * *
/REMARK * SATLOG-DATEIEN WERDEN NACH IHRER AUSWERTUNG DURCH DIE *
/REMARK * PROZEDUR GELOESCHT, REPLACEMENT-FILES BLEIBEN ERHALTEN. *
/REMARK * *
/REMARK * VORAUSSETZUNGEN: SAT-PROTOKOLLIERUNG MUSS AKTIV SEIN. DER *
/REMARK * NAME DER AKTUELLEN SATLOG-DATEI MUSS *
/REMARK * DAS DATUM MIT VIERSTELLIGER ANGABE DES *
/REMARK * JAHRES ENTHALTEN. *
/REMARK * EINGABEDATEIEN: SATLOG-DATEIEN UND/ODER REPLACEMENT- *
/REMARK * FILES, DEREN NAME DAS DATUM MIT VIER- *
/REMARK * STELLIGER ANGABE DES JAHRES ENTHAELT. *
/REMARK * AUSGABEDATEI: ANALYZE.<DATUM DER AUSGEWERTETEN DATEIEN> *
/REMARK *------------------------------------------------------------*
/ASSIGN-SYSOUT TO-FILE=BATCH.SYSOUT
/ASSIGN-SYSLST TO-FILE=BATCH.SYSLST
/ASSIGN-SYSDTA TO-FILE=*SYSCMD
/CHANGE-SAT-FILE
/SET-JOB-STEP
/MODIFY-JOB-SWITCHES ON=(4,5)
/START-EDT
@FSTAT 'SYS.SATLOG.////-*' TO 1
@PROC 1
@@RENUMBER
@@SET #L2=$
@@IF #L2 = 1 GOTO 10
@@NOTE NUR EINE DATEI GEFUNDEN -> KEINE DATEIEN VOM VORTAG
@@SET #L3 = 1
@@IF #L3:1-21 <> #L2:1-21 GOTO 20
@@NOTE DATUM DER ERSTEN GEFUNDENEN DATEI GLEICH DATUM DER LETZTEN
@@NOTE GEFUNDENEN DATEI -> ALLE DATEIEN VOM AKTUELLEN TAG
@10
@@SET #S20 = 'KEINE ANALYSE DURCHGEFÜHRT. SIEHE WARNUNG '
@@PRINT #S20 NSV
@@RETURN
@20
@@SET #L1 = 1
@@ON #L1 FIND 'SYS.SATLOG.'
@@NOTE DATUM EXTRAHIEREN
@@SET #I2 = #I1 + 1
@@SET #I3 = #I2 + 9
@@SET #S1 = #L1:#I2-#I3
@@DELETE
@@NOTE SATUT-PROZEDUR ERSTELLEN
@@QUOTE !
@@CREATE 1 : !/SET-LOGON-PARAMETERS!
@@CREATE 2 : !/ASSIGN-SYSLST TO-FILE=LST.SEL.DAILY.!,#S1
@@CREATE 2.5 : !/ASSIGN-SYSOUT TO-FILE=OUT.SEL.DAILY.!,#S1
@@CREATE 3 : !/START-SATUT!
@@NOTE DATEI DES VORHERGEHENDEN TAGES AUSWAEHLEN
@@CREATE 4 : !//SELECT-INPUT-FILES INPUT-FILES=*STD(DATE=!,#S1,!)!
@@NOTE DATEIEN NACH BESTIMMTEN VORGABEN AUSWAEHLEN :
@@CREATE 5 : !//ADD-SELECTION-CONDITIONS NAME=PRIVI, CONDITION= -!
@@NOTE BENUTZER AUSWAEHLEN
@@CREATE 6 : !// OBJ-UID IN-LIST ('US1','US2','US3') -!
@@NOTE INHALT DES ERGEBNISFELDES FESTLEGEN
@@CREATE 7 : !//AND RES EQUAL F -!
@@NOTE OBJEKT UEBER SEINE EREIGNISSE BESTIMMEN
@@CREATE 8 : !//AND EVT IN-LIST ('PST','PRT') !
@@NOTE SELEKTION DURCHFUEHREN
@@CREATE 8.5 : !//START-SELECTION FROM-FILE=*INPUT-FILES, - !
@@CREATE 8.7 : !//TO-FILE=*PAR(FILE=0, CONDITION-NAME=PRIVI) !
@@NOTE AUSGEWAEHLTE DATENSAETZE NACH SYSLST AUSGEBEN
@@CREATE 9 : !//SHOW-SELECTED-RECORDS SORT-CRITERION=*EVT, -!
@@CREATE 10 : !// FROM-FILE=0, OUTPUT=*SYSLST(LINES=114) !
@@NOTE AUSGEWAEHLTE DATENSAETZE ZUR ARCHIVIERUNG IN EINE DATEI
@@NOTE SCHREIBEN
@@CREATE 11 : !//SAVE-SELECTED-RECORDS TO-REDUCTION-NAME=ANALYZE.!,#S1
@@CREATE 12 : !//END!
@@CREATE 12.5 : !/SHOW-FILE-ATTRIBUTES ANALYZE.!,#S1
@@NOTE BEARBEITETE SATLOG-DATEIEN LOESCHEN
@@CREATE 12.7 : !/DELETE-FILE SYS.SATLOG.!,#S1,!.,IGNORE=ACCESS!
@@CREATE 14 : !/SET-JOB-STEP!
@@CREATE 15 : !/ASSIGN-SYSLST TO-FILE=*PRIMARY!
@@CREATE 15.5 : !/ASSIGN-SYSOUT TO-FILE=*PRIMARY!
@@CREATE 16 : !/EXIT-JOB SYSTEM-OUTPUT=*NONE!
@@QUOTE '
@@WRITE 'E.RUN-DAILY' O
@@SYSTEM 'ENTER-JOB E.RUN-DAILY'
@END
@DO 1
@HALT
/MODIFY-JOB-SWITCHES OFF=(4,5)
/ASSIGN-SYSDTA TO-FILE=*PRIMARY
/ASSIGN-SYSLST TO-FILE=*PRIMARY
/EXIT-JOB SYSTEM-OUTPUT=*NONE