Your Browser is not longer supported

Please use Google Chrome, Mozilla Firefox or Microsoft Edge to view the page correctly
Loading...

{{viewport.spaceProperty.prod}}

SET-Anweisung

&pagelevel(4)&pagelevel

Funktion

Die SET-Anweisung bietet mit ihren verschiedenen Formaten folgende Möglichkeiten:


Format 1

ein ganzzahliges Datenfeld, einen Index oder ein Indexdatenfeld auf einen angegebenen Wert setzen

Format 2

den Wert eines Index vermindern oder erhöhen, so dass er eine neue Tabellenelementnummer darstellt

Format 3

den Zustand von externen Schaltern ändern

Format 4

den Wert von Bedingungsvariablen setzen

Format 5

Objektreferenzen zuweisen

Format 6

Datenzeiger zuweisen

Format 7

mit Datenzeigern rechnen

Format 8

Programmzeiger zuweisen

Format 9

den letzten Ausnahmezustand zurück setzen


Format 1

SET {index-1 | bezeichner-1}... TO {index-2 | bezeichner-2 | ganzzahl-1}

Syntaxregeln

Alles, was nachfolgend über index-1 und bezeichner-1 gesagt wird, trifft in gleicher Weise auf ihre Wiederholungen zu.

  1. Jeder Index muss in einer OCCURS-Klausel in der INDEXED BY-Angabe angegeben sein.

  2. Jeder Bezeichner muss entweder ein Indexdatenfeld oder ein numerisches Festpunktdatenelement, das als eine Ganzzahl beschrieben ist, bezeichnen.

  3. Der Wert von ganzzahl-1 oder bezeichner-2 muss eine gültige Tabellenelementnummer der zugehörigen Tabelle sein. Der Compiler lässt jedoch auch andere ganzzahlige Werte zu (z.B. 0 oder negative Zahlen) - im Rahmen des erlaubten Wertebereichs für index-1 (siehe "Indizierung" ).

  4. Indizes oder Bezeichner, die dem TO vorangehen, geben das Feld an, dessen Wert gesetzt werden soll.

  5. index-2, bezeichner-2 und ganzzahl-1, die dem TO folgen, geben den Wert an, auf den das Empfangsfeld (z.B. index-1) gesetzt werden soll.

  6. Bei Ausführung der SET-Anweisung geschieht Folgendes:

    1. index-1 wird so gesetzt, dass er auf jenes Tabellenelement Bezug nimmt, dessen Elementnummer dem Tabellenelement entspricht, auf das index-2, bezeichner-2 oder ganzzahl-1 Bezug nehmen.

      Bezeichnet bezeichner-2 ein Indexdatenfeld oder gehört index-2 zu derselben Tabelle wie index-1, findet keine Konvertierung statt.

    2. Ist bezeichner-1 ein Indexdatenfeld, wird es so gesetzt, dass es entweder den gleichen Inhalt wie index-2 oder wie bezeichner-2 hat, wobei bezeichner-2 ebenso ein Indexdatenfeld ist. Es findet keine Konvertierung statt. ganzzahl-1 darf in diesem Fall nicht verwendet werden.

    3. Ist bezeichner-1 kein Indexdatenfeld, wird er auf eine Tabellennummer gesetzt, die dem Wert von index-2 entspricht. In diesem Fall darf weder bezeichner-2 noch ganzzahl-1 verwendet werden.

    Dieser Vorgang gilt auch für Wiederholungen von index-1 und bezeichner-1. Der Wert von index-2 oder bezeichner-2 wird jedesmal wie zu Beginn der Ausführung der Anweisung verwendet. Jede Subskribierung oder Indizierung für bezeichner-1 wird ausgewertet, bevor der Wert des betroffenen Datenfeldes verändert wird.

  7. Die nachstehende Tabelle gibt an, welche Kombinationen von Operanden in der SET-Anweisung zulässig sind. Die Buchstaben nach den Schrägstrichen verweisen auf die unter Punkt 6. aufgeführten Regeln; z.B. bedeutet gültig/c, dass eine Kombination von Feldern entsprechend der Regel c) gültig ist.

    Sendefeld

    Empfangsfeld

    ganzzahliges Datenfeld PIC9(n)

    Indexname INDEXED BY

    Indexname USAGE IS INDEX

    ganzzahliges Literal

    ungültig/c

    gültig/a

    ungültig/b

    ganzzahliges Datenfeld

    ungültig/c/

    gültig/a

    ungültig/b

    Indexname Indexdatenfeld

    gültig/c ungültig/c

    gültig/a gültig/a*

    gültig/b*gültig/b*

    Tabelle 31: Gültige Verwendungen der SET-Anweisung

    * = es findet keine Konvertierung statt.

  8. Wird index-2 verwendet, muss sein Wert vor Ausführung der SET-Anweisung der Nummer eines Elements der zugehörigen Tabelle entsprechen.

Beispiel 8-70

Einträge im Datenteil:

    02 TABELLE-A PICTURE XXX OCCURS 50,
               INDEXED BY IN-A1, IN-A2, IN-A3.
    02 TABELLE-B PICTURE XX OCCURS 55,
               INDEXED BY IN-B.
77 ID-1 USAGE IS INDEX.
77 D-1 PICTURE IS S999, USAGE IS COMPUTATIONAL-3.

Anweisungen im Prozedurteil siehe die folgende tabellarische Aufstellung:

Anweisung

Verwendete Operanden

Was getan wird 1)

SET IN-A2 TO IN-A1

Indexname wird auf Indexname gesetzt

Einfache Übertragung

SET IN-A1 TO D-1

Indexname wird auf numerisches Datenfeld gesetzt

Multipliziere (numerisches Datenfeld minus 1) mit der Tabellenelementlänge, um die Distanz zu erhalten.

SET IN-A1 TO ID-1

Indexname wird auf Indexdatenfeld gesetzt

Einfache Übertragung

SET IN-A1 TO 4

Indexname wird auf Literal gesetzt

Multipliziere (Literal minus 1)2) mit der Tabellenelementlänge, um die Distanz zu erhalten.

SET ID-1 TO IN-A1

Indexdatenfeld wird auf Indexname gesetzt

Einfache Übertragung

SET D-1 TO IN-A1

Numerisches Datenfeld wird auf Indexname gesetzt

Dividiere Distanz durch Tabellenelement und addiere 1 dazu, um die Tabellenelementnummer zu erhalten.

SET IN-B TO IN-A1

Indexname wird auf Indexname gesetzt (verschiedene Tabellen)

Dividiere Distanz (z.B. Inhalt von IN-A1) durch die Tabellenelementlänge von TABELLE-A und addiere 1, um die Tabellenelementnummer zu erhalten. Multipliziere dann (Tabellenelementnummer minus 1) mit der Tabellenelementlänge der TABELLE-B, um die Distanz zu erhalten.

1) Wegen des Zusammenhangs zwischen Tabellenelementnummer und Distanz siehe Abschnitt "Indizierung".
2) Wird zum Übersetzungszeitpunkt ausgerechnet, beim Ablauf einfache Übertragung.

Beispiel 8-71

02  TABELLE-A OCCURS 50 TIMES
              INDEXED BY IND-1,IND-2,PIC 999.
 .
 .
 .
SET IND-1 TO 5.
SET IND-2 TO 7.
SET IND-1,TABELLE-A (IND-1) TO IND-2.

Die dritte SET-Anweisung ist gleichwertig mit folgenden zwei Anweisungen, die in der Reihenfolge ausgeführt werden, in der sie aufgeschrieben sind:

Anweisung

Wirkung

SET IND-1 TO IND-2

IND-1 wird auf Tabellenelementnummer 7, den aktuellen Wert von IND-2, gesetzt

SET TABELLE-A (IND-1) TO IND-2

Da die erste SET-Anweisung IND-1 auf 7 setzt, gilt TABELLE-A (IND-1) =TABELLE-A (7). Deshalb setzt diese Anweisung TABELLE-A (7) auf 7.

Format 2

SET {index-3}... {UP BY | DOWN BY} {bezeichner-3 | ganzzahl-2}

Syntaxregeln

  1. Jeder Index muss in einer OCCURS-Klausel in der INDEXED BY-Angabe angegeben sein.

  2. index-3... gibt den Speicherindex an, dessen Wert verändert werden soll.

  3. bezeichner-3 muss ein numerisches Festpunktdatenelement sein, das als Ganzzahl beschrieben ist.

  4. ganzzahl-2 muss eine ganze Zahl ungleich 0 sein und darf ein positives Vorzeichen enthalten.

  5. UP BY oder DOWN BY gibt an, dass der Inhalt des angegebenen Index um einen bestimmten Wert erhöht (UP BY) oder vermindert (DOWN BY) werden soll. Dieser Wert entspricht der Wiederholungszahl, die den Wert von bezeichner-3 oder ganzzahl-2 darstellt.

Beispiel 8-72

02  TABELLE-A PICTURE X(20) OCCURS 5 INDEXED BY IND-1.
     .
     .
     .
SET IND-1 TO 4.
SET IND-1 UP BY 2.
SET IND-1 DOWN BY 3.

Die erste SET-Anweisung setzt den Index IND-1 auf Tabellenelementnummer 4, die zweite setzt ihn auf 6 (d.h., 4+2), und die dritte setzt ihn auf 3 (d.h. 6-3).

Format 3

SET { {merkname-1}... TO {ON | OFF} }...


Syntaxregel

  1. Jedem Merknamen muss ein externer Schalter zugeordnet sein, dessen Zustand verändert werden kann (siehe "SPECIAL-NAMES-Paragraf").

Format 4

SET { {bedingungsname-1}... TO {TRUE | FALSE } }...


Syntaxregeln

  1. bedingungsname-1 muss mit einer Bedingungsvariablen verknüpft sein (siehe "Bedingungsnamen-Bedingung").

  2. Falls die FALSE-Angabe in der SET-Anweisung benutzt wird, muss die FALSE-Angabe in der VALUE-Klausel des Bedingungsnamens vorhanden sein.

Allgemeine Regeln

  1. Das in der VALUE-Klausel angegebene, mit bedingungsname-1 verknüpfte Literal wird entsprechend den Regeln der VALUE-Klausel (siehe "VALUE-Klausel ") in die Bedingungsvariable eingesetzt.

    Wenn der Bedingungsvariable jedoch eine Gruppe untergeordnet ist, wird deren Länge entsprechend den Regeln der OCCURS-Klausel bestimmt (siehe Abschnitt "OCCURS-Klausel").

    Ist in der VALUE-Klausel mehr als ein Literal angegeben, wird die Bedingungsvariable auf den Wert des an erster Stelle stehenden Literals der VALUE-Klausel gesetzt.

  2. Sind mehrere Bedingungsnamen angegeben, wird so verfahren, als ob für jeden einzelnen Bedingungsnamen eine eigene SET-Anweisung geschrieben worden wäre.

  3. Bei "SET...TO FALSE" wird das Literal aus der FALSE-Angabe in der VALUE-Klausel, die mit bedingungsname verknüpft ist, entsprechend den Regeln der VALUE-Klausel in die Bedingungsvariable eingesetzt (siehe "SET bedingungsname TO TRUE").

Beispiel 8-73

IDENTIFICATION DIVISION.
PROGRAM-ID. SETZEN.
ENVIRONMENT DIVISION.
CONFIGURATION SECTION.
SPECIAL-NAMES.
    TERMINAL IS T.
DATA DIVISION.
WORKING-STORAGE SECTION.
01  BEISPIEL1.
    02  ARBEITSTAG  PICTURE X.
	    88 MONTAG  VALUE "1".
	    88 FREITAG VALUE "5".
01 BEISPIEL2.
	02  WOCHENTAG PIC X.
    	88 ARBEITSTAGE VALUE "1" "2" "3" "4" "5".
PROCEDURE DIVISION.
P1 SECTION.
SETZEN.
    SET FREITAG TO TRUE.
    DISPLAY "Arbeitstag =" ARBEITSTAG UPON T.
    SET ARBEITSTAGE TO TRUE.
    DISPLAY "Wochentag =" WOCHENTAG UPON T.
SCHLUSS.
    STOP RUN.

Nach Ausführung der ersten SET-Anweisung steht im Datenfeld ARBEITSTAG (Bedingungsvariable) das Literal, das in der VALUE-Klausel dem Bedingungsnamen FREITAG zugeordnet ist: "5".

Nach Ausführung der zweiten SET-Anweisung steht im Datenfeld WOCHENTAG das Literal "1".

Format 5

SET {bezeichner-5}... TO bezeichner-6

Syntaxregeln

  1. bezeichner-5 muss eine Objektreferenz sein, die als Empfangsfeld zulässig ist.

  2. bezeichner-6 muss ein Klassenname oder eine Objektreferenz sein; die vordefinierte Objektreferenz SUPER darf nicht angegeben werden.

  3. Ist das Daten-Element, auf welches bezeichner-5 verweist, eine universelle Objektreferenz, dann sind für bezeichner-6 alle Daten der Klasse objekt zugelassen.

  4. Ist das Daten-Element, auf welches bezeichner-5 verweist, mit einem Interfacenamen bezeichnet, der die Schnittstelle int-1 (interface-1) angibt, dann darf das Daten-Element, auf welches bezeichner-6 verweist, nur eines der folgenden sein:

    1. eine Objektreferenz, die einen Interfacenamen für eine Schnittstelle angibt, welche mit int-1 konform ist;

    2. eine Objektreferenz, die einen Klassennamen gemäß den folgenden Regeln angibt:

      • ist sie mit einer FACTORY-Angabe beschrieben , muss die Schnittstelle des Fabrikobjektes der spezfizierten Klasse zu int-1 konform sein;

      • ist sie ohne FACTORY-Angabe beschrieben, muss die Schnittstelle der Objekte der spezifizierten Klasse zu int-1 konform sein;

    3. eine Objektreferenz, mit ACTIVE-CLASS-Angabe, gemäß den folgenden Regeln:

      • ist sie mit einer FACTORY-Angabe beschrieben, muss die Schnittstelle des Fabrikobjektes der Klasse, die das Daten-Element enthält, auf welches bezeichner-6 verweist, zu int-1 konform sein;

      • ist sie ohne FACTORY-Angabe beschrieben, muss die Schnittstelle der Objekte der Klasse, die das Daten-Element enthält, auf welches bezeichner-6 verweist, mit int-1 konform sein;

    4. eine Klasse, bei der die Schnittstelle ihres Fabrikobjektes zu int-1 konform ist;

    5. die vordefinierte Objektreferenz SELF, wobei die Schnittstelle der Quelleinheit, welche die SET-Anweisung enthält, zu int-1 konform ist,

    6. die vordefinierte Objektreferenz NULL.
  5. Wenn das Daten-Element, auf welches bezeichner-5 verweist, mit einem Klassennamen bezeichnet wird, dann muss das Daten-Element, auf welches bezeichner-6 verweist, eines der folgenden sein:

    1. eine Objektreferenz, die mit einem Klassennamen bezeichnet ist, gemäß folgender Regeln:

      • ist das Daten-Element, auf welches bezeichner-5 verweist, mit der ONLY-Angabe beschrieben, dann muss das Daten-Element, auf welches bezeichner-6 verweist, auch mit der ONLY-Angabe beschrieben werden. Weiter muss der Klassenname, der in der Beschreibung des Daten-Elementes, auf das bezeichner-6 Bezug nimmt, definiert ist, identisch sein mit dem Klassennamen, der in der Beschreibung des Daten-Elementes angegeben ist, auf das bezeichner-5 verweist;

      • ist das Daten-Element, auf welches bezeichner-5 verweist, ohne ONLY-Angabe beschrieben, dann muss der Klassenname, der in der Beschreibung des Daten Elementes, auf das bezeichner-6 Bezug nimmt, spezifiziert ist, auf dieselbe Klasse oder untergeordnete Klasse verweisen, die in der Beschreibung des Daten-Elementes angegeben ist, auf welches bezeichner-5 verweist;

      • das Vorhandensein oder das Fehlen der FACTORY-Angabe muss der Angabe bei bezeichner-5 entsprechen.

    2. eine Objektreferenz, die mit einer ACTIVE-CLASS-Angabe beschrieben wird, gemäß den folgenden Regeln:

      • im Daten-Element, auf welches bezeichner-5 verweist, darf keine ONLY-Angabe definiert sein;

      • die Klasse, die das Daten-Element enthält, auf welches bezeichner-6 verweist, muss dieselbe Klasse oder eine untergeordnete Klasse von der sein, die in der Beschreibung des Daten-Elementes spezifiziert ist, auf welches bezeichner-5 verweist;

      • das Vorhandensein oder das Fehlen der FACTORY-Angabe muss der Angabe bei bezeichner-5 entsprechen.

    3. die vordefinierte Objektreferenz SELF, gemäß den folgenden Regeln:

      • das Daten-Element, auf welches bezeichner-5 verweist, darf keine ONLY-Angabe enthalten;

      • die Klasse des Objektes, welches die SET-Anweisung enthält, muss dieselbe Klasse oder untergeordnete Klasse von der sein, die in der Beschreibung des Daten-Elementes spezifiziert ist, auf welches bezeichner-5 verweist;

      • ist im Daten-Element, auf welches bezeichner-5 verweist, keine FACTORY-Angabe beschrieben, dann muss die Quelleinheit, welche die SET-Anweisung enthält, ein Instanzobjekt sein;

      • enthält die Beschreibung des Daten-Elementes, auf das bezeichner-5 verweist, eine FACTORY-Angabe, dann muss die Quelleinheit, welche die SET-Anweisung enthält, ein Fabrikobjekt sein.

    4. ein Klassenname, wenn Folgendes gilt:

      • die Beschreibung des Daten-Elementes, auf das bezeichner-5 verweist, enthält eine FACTORY-Angabe,

      • ist das Datenelement, auf welches bezeichner-5 verweist, mit der ONLY-Angabe beschrieben, dann muss das derselbe Klassenname sein. Anderenfalls darf es auch eine Unterklasse derjenigen Klasse sein, mit der das Datenelement, auf das bezeichner-5 verweist, beschrieben ist.

    5. die vordefinierte Objektreferenz NULL.

  6. Enthält die Beschreibung des Daten-Elementes, auf das bezeichner-5 verweist, eine ACTIVE-CLASS-Angabe, dann muss das Daten-Element, auf welches bezeichner-6 Bezug nimmt, eines der folgenden sein:

    1. eine Objektreferenz, die mit einer ACTIVE-CLASS-Angabe beschrieben ist, wobei das Vorhandensein oder das Fehlen der FACTORY-Angabe analog sein muss, wie im Daten-Element beschrieben, auf das bezeichner-5 verweist;

    2. die vordefinierte Objektreferenz SELF, gemäß den folgenden Regeln:

      • ist im Daten-Element, auf welches bezeichner-5 verweist, keine FACTORY-Angabe beschrieben, dann muss das Objekt, welches die SET-Anweisung enthält, ein Instanzobjekt sein;

      • enthält die Beschreibung des Daten-Elementes, auf das bezeichner-5 verweist, eine FACTORY-Angabe, dann muss das Objekt, welches die SET-Anweisung enthält, ein Fabrikobjekt sein.

    3. die vordefinierte Objektreferenz NULL.

Allgemeine Regeln

  1. Ist bezeichner-6 eine Objektreferenz, dann wird diese Referenz in das Datenelementbezeichner-5 übertragen und in jede seiner Wiederholungen in der angegebenen Reihenfolge.

  2. Ist bezeichner-6 ein Klassenname, dann wird eine Referenz auf das Fabrikobjekt der Klasse in das Daten-Element bezeichner-5 übertragen und in jede seiner Wiederholungen in der angegebenen Reihenfolge.

Konformität der Objektreferenzen bei SET-Anweisungen

Die folgende Tabelle zeigt zusammenfassend die Kombinationen der Objektreferenzen im Sende- und Empfangsfeld.


Kombination

immer erlaubt:

o.k.

bedingt erlaubt:

Bedingung

verboten:

----


Notation für Bedingungen

A > B

Interface A ist konform zu Interface B:

A >> B

Klasse A ist Unterklasse von B:

A == B

Klasse A ist die gleiche Klasse wie B:


Abkürzungen

i5

Interface des Empfangsfeldes

i6

Interface des Sendefeldes

c5

Klasse des Empfangfeldes

c6

Klasse des Sendefeldes

c

Klasse entsprechend dem Namen

C

Klasse, in der die SET-Anweisung steht1

FI(X)

Interface des Factory-Objekts der Klasse X

OI(X)

Interface eines Objekt-Objekts der Klasse X

1 Darunter ist die Klasse zu verstehen, in der die Methode definiert ist, die die SET-Anweisung enthält und nicht eine Klasse, die diese Methode erbt.


Sendefeld Objektreferenz USAGE

Empfangsfeld
Objektreferenz
USAGE

(universell)

interface
i6

FACTORY klassen-
name
c6

FACTORY klassen-
name
ONLY
c6

klassen-
name
c6

klassen-
name
ONLY
c6

FACTORY ACTIVE-
CLASS
C

ACTIVE-
CLASS
C

(universell)


o.k.

o.k.

o.k.

o.k.

o.k.

o.k.

o.k.

o.k.

interface

i5

---

i6 > i5

FI(c6)>i5

FI(c6)>i5

OI(c6)>i5

OI(c6)>i5

FI(C)>i5

OI(C)>i5

FACTORY klassenname

c5

---

---

c6>>==c5

c6>>==c5

---

---

C>>==c5

---

FACTORY klassenname ONLY

c5

---

---

---

c6==c5

---

---

---

---

klassenname

c5

---

---

---

---

c6>>==c5

c6>>==c5

---

C>>==c5

klassenname ONLY

c5

---

---

---

---

---

c6==c5

---

---

FACTORY ACTIVE-CLASS

C

---

---

---

---

---

---

o.k.

---

-ACTIVE-CLASS

C

---

---

---

---

---

---

---

o.k.

Tabelle 32: Kombination der Objektreferenzen im Sende- und Empfangsfeld



Sendefelder

klassenname

Objektreferenz SELF

NULL

Empfangsfeld
Objektreferenz
USAGE

c

in Factory-
Methode C

in Objekt- M
ethode C


(universell)


o.k.

o.k.

o.k.

o.k.

interface

i5

FI(c)>i5

FI(C)>i5

OI(C)>i5

o.k.

FACTORY klassenname

c5

c>>==c5

C>>==c5

---

o.k.

FACTORY klassenname ONLY

c5

c==c5

---

---

o.k.

klassenname

c5

---

---

C>>==c5

o.k.

klassenname ONLY

c5

---

---

---

o.k.

FACTORY ACTIVE-CLASS

C

---

o.k.

---

o.k.

ACTIVE-CLASS

C

---

---

o.k.

o.k.

Tabelle 33: Kombination der Objektreferenzen im Sende- und Empfangsfeld

Format 6

SET {ADDRESS OF datenname-1 | bezeichner-7 ...} TO bezeichner-8

Syntaxregeln

  1. bezeichner-7 und bezeichner-8 müssen ein Datenelement der Kategorie datenzeiger referenzieren.

  2. datenname-1 muss ein Datenelement sein, das mit der BASED-Klausel spezifiziert ist. Siehe aber auch Compiler-Option PERMIT-STANDARD-DEVIATION.

  3. datenname-1 darf nicht mit der ANY LENGTH-Klausel definiert sein.

  4. Ist bezeichner-7 ein typbezogener Zeiger, muss bezeichner-8 entweder die vordefinierte Adresse NULL sein oder ein typbezogener Zeiger auf den gleichen Typ. Ist der datenname-1 stark typisiert, muss bezeichner-8 ein typbezogener Zeiger auf den gleichen Typ sein.
    Ist bezeichner-8 ein typbezogener Zeiger, muss entweder bezeichner-7 ein typbezogener Zeiger auf den gleichen Typ sein oder datenname-1 muss vom gleichen Typ typisiert sein, an den bezeichner-8 gebunden ist.

Allgemeine Regeln

  1. Ist bezeichner-7 angegeben, dann wird die durch bezeichner-8 spezifizierte Adresse in dem durch bezeichner-7 referenzierten Datenelement abgelegt.

  2. Ist datenname-1 angegeben, dann wird die durch bezeichner-8 spezifizierte Adresse dem durch datenname-1 referenzierten Datenelement zugeordnet.

Format 7

SET bezeichner-9 ... {UP | DOWN} BY {bezeichner-10 | ganzzahl-3}

Syntaxregeln

  1. bezeichner-10 muss ein numerisches Festpunktdatenfeld sein, das als Ganzzahl beschrieben ist.

  2. ganzzahl-3 muss eine ganze Zahl oder 0 sein, die ein Vorzeichen enthalten darf.

  3. bezeichner-9 muss von der Kategorie Datenzeiger sein.

  4. bezeichner-9 darf kein typbezogener Zeiger sein, bei der die zugehörige Typdeklaration die Angabe STRONG hat.

Allgemeine Regel

  1. Die Adresse, die im Zeigerdatenfeld enthalten ist, wird erhöht, wenn UP angegeben istbzw. erniedrigt, wenn DOWN angegeben ist und zwar um die Anzahl Bytes, die durch bezeichner-10 oder ganzzahl-3 angegeben ist.

Format 8

SET {bezeichner-11}... TO bezeichner-12

Syntaxregeln

  1. bezeichner-11 muss ein Datenfeld der Kategorie Programmzeiger sein. bezeichner-12 muss von der Kategorie Programmzeiger sein.

Allgemeine Regel

  1. Die mit bezeichner-12 bezeichnete Adresse wird in jedes Datenfeld bezeichner-11 in der angegebenen Reihenfolge gespeichert.

Format 9

SET LAST EXCEPTION TO OFF

Allgemeine Regel

  1. Der letzte Ausnahmezustand wird zurückgesetzt, d.h. er zeigt an, dass kein Ausnahmezustand ausgelöst wurde.

Powered by Atlassian Confluence and Scroll Viewport.