Automatische Versionserhöhung bei Konvention STD-TREE

/start-lms

//modify-logging-parameters logging=*maximum ----------------------------   (1) 

//open-library library=bsp12.bib,mode=*update ---------------------------   (2)

LIBRARY IS CLEARED AND PREPARED

//modify-type-attributes type=s,convention=*std-tree --------------------   (3)

//show-type-attributes type=s -------------------------------------------   (4)

INPUT  LIBRARY= :1OSQ:$USER.BSP12.BIB
TYPE      = S
SUPER-TYPE = *NONE

BASE-TYPE  = S
CONVENTION = *STD-TREE

INIT-ELEM-P= *NONE

ADMINISTRAT= *NONE

STORAGE    = *NONE        WR-CONTROL = *NONE

//add to-element=library-element(element=test(version=*increment),type=s) - (5)

input1

*END

INPUT  SYSDTA
OUTPUT LIBRARY= :1OSQ:$USER.BSP12.BIB

OUTPUT ELEMENT= (S)TEST/001.001(0001)/2013-03-01

        ADD (S)TEST/001.001(0001)/2013-03-01

(1)	Zusätzlich zu Fehlermeldungen werden auch Erfolgsmeldungen protokolliert.
(2)	Die Bibliothek BSP12.BIB wird zum Lesen und Schreiben geöffnet; es ist kein Element vom Typ S vorhanden.
(3)	Einrichten der Konvention STD-TREE für den Elementtyp S.
(4)	Anzeigen der Typattribute für den Elementtyp S zur Kontrolle.
(5)	Erzeugen des ersten Elements über *SYSDTA. Das Element wird unter Typ S mit Namen test über die automatische Versionserhöhung erzeugt.

//add to-element=library-element(element=test(version=*increment),type=s)   (6) 

input1

*END

INPUT  SYSDTA
OUTPUT LIBRARY= :1OSQ:$USER.BSP12.BIB

OUTPUT ELEMENT= (S)TEST/001.002(0001)/2013-03-01

        ADD (S)TEST/001.002(0001)/2013-03-01

//add to-element=(element=test(version=*increment,base=1.1),type=s) ------  (7)

*END

INPUT  SYSDTA

OUTPUT LIBRARY= :1OSQ:$USER.BSP12.BIB

OUTPUT ELEMENT= (S)TEST/001.001.001.001(0001)/2013-03-01

%  LMS0095 INPUT DATA RECORDS MISSING

         ADD (S)TEST/001.001.001.001(0001)/2013-03-01

//add-element to-element=library-element(element=test(version=2.1),type=s   (8)

input1

*END

INPUT  SYSDTA
OUTPUT LIBRARY= :1OSQ:$USER.BSP12.BIB

OUTPUT ELEMENT= (S)TEST/002.001(0001)/2013-03-01

        ADD (S)TEST/002.001(0001)/2013-03-01

//add to-element=(element=test(version=*increment,base=1.1.1.*),type=s) --- (9)

input1

*END

INPUT  SYSDTA
OUTPUT LIBRARY= :1OSQ:$USER.BSP12.BIB

OUTPUT ELEMENT= (S)TEST/001.001.001.002(0001)/2013-03-01

        ADD (S)TEST/001.001.001.002(0001)/2013-03-01

//add to-element=(element=test(version=*highest-existing),type=s), -
//    write-mode=*any ---------------------------------------------------- (10)

input1

*END

INPUT  SYSDTA
OUTPUT LIBRARY= :1OSQ:$USER.BSP12.BIB

OUTPUT ELEMENT= (S)TEST/002.001(0002)/2013-03-01

        ADD (S)TEST/002.001(0002)/2013-03-01 , OUTPUT REPLACED

(6)	Weiterführen der Sequenz mit *INCREMENT, d.h. es wird ein zweites Element mit gleichem Namen und Typ, aber um eins erhöhter Version erzeugt.
(7)	Eröffnen eines Nebenzweigs an der Version 1.1
(8)	Erzeugen eines Elementes mit gleichem Typ und Namen, aber mit einer explizit angegebenen Version.
(9)	Weiterführung des Nebenzweigs mit Präfix 1.1.1.
(10)	Überschreiben der höchsten Version mit Typ S und Namen TEST.

//show-element-attributes ------------------------------------------------  (11) 

INPUT  LIBRARY= :1OSQ:$USER.BSP12.BIB
TYP NAME VERSION        (VAR#) DATE
(S) TEST 001.001 . . . . (0001) 2013-03-01

(S) TEST 001.001.001.001 (0001) 2013-03-01

(S) TEST 001.001.001.002 (0001) 2013-03-01

(S) TEST 001.002 . . . . (0001) 2013-03-01

(S) TEST 002.001 . . . . (0002) 2013-03-01

      5 (S)-ELEMENT(S) IN THIS TABLE OF CONTENTS

//end --------------------------------------------------------------------  (12)

(11)	Ausgeben des Inhaltsverzeichnis der Bibliothek BSP12.BIB. Die Bibliothek enthält fünf Elemente mit gleichem Namen und Typ, aber unterschiedlicher Versions- und Variantennummer.
(12)	Beenden des LMS-Laufs.