Automatische Versionserhöhung bei Konvention STD-SEQUENCE

Es sollen Elemente in einem fest vorgegebenen Versionsformat in eine Bibliothek aufgenommen werden, wobei die Versionserhöhung automatisch erfolgen soll.

/start-lms

//modify-logging-parameters logging=*maximum ------------------------------  (1) 

//open-library library=bsp11.bib,mode=*update -----------------------------  (2)

LIBRARY IS CLEARED AND PREPARED

//modify-type-attributes type=s,convention=*std-sequence(example=v001) ----  (3)

//show-type-attributes type=s ---------------------------------------------  (4)

INPUT  LIBRARY= :1OSQ:$USER.BSP11.BIB
TYPE      = S
SUPER-TYPE = *NONE

BASE-TYPE  = S
CONVENTION = *STD-SEQUENCE

EXAMPLE    = V001
INIT-ELEM-P= *NONE

ADMINISTRAT= *NONE

STORAGE    = *NONE        WR-CONTROL = *NONE

//add to-element=library-element(element=test(version=*increment),type=s) -  (5)

input1

*END

INPUT  SYSDTA
OUTPUT LIBRARY= :1OSQ:$USER.BSP11.BIB

OUTPUT ELEMENT= (S)TEST/V001(0001)/2013-03-01

        ADD (S)TEST/V001(0001)/2013-03-01

(1)	Zusätzlich zu Fehlermeldungen werden auch Erfolgsmeldungen protokolliert.
(2)	Die Bibliothek BSP11.BIB wird zum Lesen und Schreiben geöffnet; es ist kein Element vom Typ S vorhanden.
(3)	Einrichten der Konvention STD-SEQUENCE für Typ S mit dem in EXAMPLE vorgegebenen Beispiel für das Versionsformat.
(4)	Anzeigen der Typattribute für den Elementtyp S zur Kontrolle.
(5)	Erzeugen des ersten Elements über *SYSDTA. Das Element wird unter Typ S mit Namen test über die automatische Versionserhöhung erzeugt.

//add-element to-element=(element=test(version=*increment),type=s) ------   (6)  

input1

*END

INPUT  SYSDTA
OUTPUT ELEMENT= (S)TEST/V002(0001)/2013-03-01

        ADD (S)TEST/V002(0001)/2013-03-01

//add to-element=library-element(element=test(version=w001),type=s) -----   (7)

input1

*END

INPUT  SYSDTA
OUTPUT ELEMENT= (S)TEST/W001(0001)/2013-03-01

        ADD (S)TEST/W001(0001)/2013-03-01

//add to-element=library-element(element=test(version=999),type=s) ------   (8)

input1

*END

OUTPUT ELEMENT= (S)TEST/999/2013-03-01

%  LMS0024 ERROR ON LIBRARY ':1OSQ:$USER.BSP11.BIB', *** PLAM ERROR CODE '0476'.
%  PLA0476 VERSION OR PREFIX NOT ACCORDING TO EFFECTIVE CONVENTION
     NO ADD (S)TEST/999/2013-03-01 , ERROR OCCURRED
SKIPPED:input1

//add to-element=(element=test(version=*highest-existing),type=s), -
//    write-mode=*any ---------------------------------------------------   (9)

input1

*END

INPUT  SYSDTA
OUTPUT ELEMENT= (S)TEST/W001(0002)/2013-03-01

        ADD (S)TEST/W001(0002)/2013-03-01 , OUTPUT REPLACED

(6)	Weiterführen der Sequenz mit *INCREMENT, d.h. es wird ein zweites Element mit gleichem Namen und Typ, aber um eins erhöhter Version erzeugt.
(7)	Weiterführen der Sequenz mit Versionswechsel, d.h. es wird ein drittes Element mit gleichem Namen und Typ, aber durch die explizite Angabe der Version mit der Version W001 erzeugt.
(8)	Es wird versucht, ein weiteres Element aufzunehmen, das nicht ein der Konvention STD-SEQUENCE entsprechendes Versionsformat besitzt. Diese Anweisung wird von LMS zurückgewiesen.
(9)	Überschreiben der höchsten Version mit Typ S und Namen test.

//show-element-attributes -------------------------------------------------- (10) 

INPUT  LIBRARY= :1OSQ:$USER.BSP11.BIB
TYP NAME VER  (VAR#) DATE        NAME VER  (VAR#) DATE
(S) TEST V001 (0001) 2013-03-01   TEST V002 (0001) 2013-03-01
(S) TEST W001 (0002) 2013-03-01

      3 (S)-ELEMENT(S) IN THIS TABLE OF CONTENTS

//end ---------------------------------------------------------------------- (11)

(10)	Übersicht über die vorhandenen Elemente.
(11)	Beenden des LMS-Laufs.