Mit dem Aufruf CALL "NCANCEL"... können Sie FT-Aufträge zurücknehmen bzw. die Dateiübertragung abbrechen. openFT (BS2000) löscht die FT-Aufträge, die den angegebenen Auswahlkriterien entsprechen, im FT-Auftragsbuch und bricht gegebenenfalls die zugehörige Dateiübertragung ab. Der Funktionsumfang entspricht dem Kommando CANCEL-FILE-TRANSFER (NCANCEL)
Aufruf
Die Funktion können Sie wie folgt aufrufen:
CALL "NCANCEL" USING FT-NCANCEL-LIST FT-RETURN-INFO.
FT-NCANCEL-LIST
Der Bereich FT-NCANCEL-LIST beschreibt die Parameterliste für den NCANCEL-Aufruf. FT-NCANCEL-LIST muss in der WORKING-STORAGE SECTION definiert sein und kann mit der Anweisung
COPY FTNCAN OF linkname.
dorthin kopiert werden.
Vor dem Aufruf müssen Sie die gewünschten Felder ausfüllen. Soll ein Parameter nicht angegeben bzw. auf den Standardwert Bezug genommen werden, so muss diesem Feld der Wert LOW-VALUE zugewiesen werden.
FT-NCANCEL-LIST ist folgendermaßen definiert:
01 FT-NCANCEL-LIST.
*
02 FILLER PIC X(4) VALUE "1000".
*
02 USER-PARAMETERS.
*
05 TRANSFER-ID PIC X(10).
88 SELECT-ALL VALUE LOW-VALUE.
*
05 SELECT-PARAMETER.
*
10 OWNER-IDENTIFICATION PIC X(8).
88 OWN VALUE LOW-VALUE.
88 SELECT-ALL VALUE " ".
*
10 INITIATOR PIC X(1).
88 SELECT-ALL VALUE LOW-VALUE.
88 LOCAL VALUE "L".
88 REMOTE VALUE "R".
*
10 PARTNER-NAME PIC X(200).
88 SELECT-ALL VALUE LOW-VALUE.
*
10 FILE-NAME PIC X(512).
88 SELECT-ALL VALUE LOW-VALUE.
10 LIBRARY PIC X(56).
88 SELECT-ALL VALUE LOW-VALUE.
10 ELEMENT PIC X(64).
88 SELECT-ALL VALUE LOW-VALUE.
10 TYP PIC X(8).
88 SELECT-ALL VALUE LOW-VALUE.
10 VERSION PIC X(24).
88 SELECT-ALL VALUE LOW-VALUE.
*
10 MONJV PIC X(56).
88 NONE VALUE LOW-VALUE.
*
10 JV-PASSWORD PIC X(11).
88 NONE VALUE LOW-VALUE.
*
05 FORCE-CANCELLATION PIC X(1).
88 NO VALUE LOW-VALUE.
88 YES VALUE "Y".
Die am Anfang der Struktur stehende Versionsangabe dient zur Identifikation des COPY-Elements und darf vom Benutzer nicht überschrieben werden.
Wenn im NCANCEL-Aufruf mehrere Auswahlkriterien angegeben werden, kann ein Auftrag überbestimmt sein, zum Beispiel durch Angaben für TRANSFER-ID und MONJV. Wenn in einem solchen Fall die Kriterien einander widersprechen, wird der NCANCEL-Aufruf nicht ausgeführt.
Der Wert YES darf nur gesetzt werden, wenn eine Transfer-ID im Feld TRANSFER-ID explizit spezifiziert wird. Der Auftrag muss vorher bereits mit FORCE-CANCELLATION=NO abgebrochen worden sein und ist nur möglich, wenn die Kennung das FT-ADM Privileg besitzt.
Beschreibung der Datenfelder
Die Parameter der FT-NCANCEL-LIST haben dieselben Namen und Funktionen wie die entsprechenden Operanden des Kommandos CANCEL-FILE-TRANSFER (NCANCEL). Beachten Sie daher bitte die entsprechende Kommandobeschreibung im Handbuch "openFT (BS2000) - Kommandoschnittstelle".
Beispiel NCANCEL
***************************************************************
* BEISPIEL: *
* *
* ABBRECHEN EINES DATEIUEBERTRAGUNGSAUFTRAGS *
* AUS EINEM COBOL-PROGRAMM *
***************************************************************
IDENTIFICATION DIVISION.
PROGRAM-ID. NCA.
*
ENVIRONMENT DIVISION.
CONFIGURATION SECTION.
SPECIAL-NAMES.
TERMINAL IS TERM.
*
DATA DIVISION.
WORKING-STORAGE SECTION.
77 MAIN-RCODE-STRING PIC -ZZZZ9.
77 SUB-RCODE-STRING PIC -ZZZZ9.
COPY FTNCAN OF FTLIB.
COPY FTRETC OF FTLIB.
*
PROCEDURE DIVISION.
STEUER SECTION.
ST-01.
*
*TRANS-ID-EINLESEN.
DISPLAY "BITTE TRANSFER-ID EINGEBEN" UPON TERM.
ACCEPT TRANSFER-ID IN FT-NCANCEL-LIST FROM TERM.
*
*NCANCEL-AUFRUFEN.
CALL "NCANCEL" USING FT-NCANCEL-LIST FT-RETURN-INFO.
*
*ERGEBNIS-BEHANDLUNG.
IF OKAY IN MAIN-RETURN-CODE
DISPLAY "OKAY: DATEIUEBERTRAGUNGSAUFTRAG ABGEBROCHEN"
UPON TERM
ELSE
MOVE MAIN-RETURN-CODE TO MAIN-RCODE-STRING
MOVE SUB-RETURN-CODE TO SUB-RCODE-STRING
DISPLAY "UEBERTRAGUNGSABBRUCH ABGELEHNT" UPON TERM
DISPLAY "MAIN-RETURN-CODE: " MAIN-RCODE-STRING
" SUB-RETURN-CODE: " SUB-RCODE-STRING
UPON TERM.
ST-99.
STOP RUN.