Mit dem Aufruf CALL "NDEL"... können Sie eine Datei in einem FT-Partnersystem löschen. Der Funktionsumfang entspricht dem Kommando DELETE-REMOTE-FILE.
Aufruf
Die Funktion können Sie wie folgt aufrufen:
CALL "NDEL" USING FT-NDEL-LIST FT-RETURN-INFO.
FT-NDEL-LIST
Der Bereich FT-NDEL-LIST beschreibt die Parameterliste für den NDEL-Aufruf. FT-NDEL-LIST muss in der WORKING-STORAGE SECTION definiert sein und kann mit der Anweisung
COPY FTNDEL OF linkname.
dorthin kopiert werden.
Vor dem ersten NDEL-Aufruf sollten die Parameterfelder mit der Anweisung
MOVE LOW-VALUE TO USER-PARAMETERS IN FT-NDEL-LIST.
gelöscht werden.
Vor einem weiteren NDEL-Aufruf müssen Sie die gewünschten Felder ausfüllen. Soll ein Parameter nicht angegeben werden bzw. auf den Standardwert Bezug genommen werden, so muss diesem Feld der Wert LOW-VALUE zugewiesen werden.
FT-NDEL-LIST ist folgendermaßen definiert:
01 FT-NDEL-LIST.
*
02 FILLER PIC X(4) VALUE "1000".
*
02 USER-PARAMETERS.
*
05 PARTNER-NAME PIC X(200).
*
05 FILE-NAME PIC X(512).
88 NOT-SPECIFIED VALUE LOW-VALUE.
*
05 FILE-PASSWORD PIC X(64).
88 NONE VALUE LOW-VALUE.
05 FILE-PASSWD-ATTR PIC X(1).
88 GRAPHIC VALUE LOW-VALUE.
88 OCTET VALUE "O".
*
05 USER-DEF-ADMISSION PIC X(67).
88 NONE VALUE LOW-VALUE.
05 USER-DEF-ADM-ATTR PIC X(1).
88 GRAPHIC VALUE LOW-VALUE.
88 OCTET VALUE "O".
05 TRANSFER-ADMISSION.
10 USER-ID PIC X(67).
10 ACCOUNT PIC X(64).
88 NONE VALUE LOW-VALUE.
10 PASSWORD PIC X(64).
88 NONE VALUE LOW-VALUE.
05 USER-PASSWD-ATTR PIC X(1).
88 GRAPHIC VALUE LOW-VALUE.
88 OCTET VALUE "0".
Die am Anfang der Struktur stehende Versionsangabe dient zur Identifikation des COPY-Elements und darf vom Benutzer nicht überschrieben werden.
Durch einen NDEL-Aufruf werden keine Werte in der Struktur FT-NDEL-LIST geändert.
Die Felder sind linksbündig zu beschreiben und rechtsbündig mit Leerzeichen aufzufüllen (Standard bei der COBOL-MOVE-Anweisung für Zeichenketten).
Felder, die keine Angaben enthalten sollen, sind mit der Zuweisung LOW-VALUE zu kennzeichnen.
Bei Nichtangabe eines Parameters werden wie beim DELETE-REMOTE-FILE-Kommando die Standardwerte abgesetzt.
Alle weiteren Werte, die an der Kommandoschnittstelle in Hochkommata eingeschlossen sein müssen, haben diese Hochkommata an der Programmschnittstelle nicht.
Kennwörter mit Integer-Wert müssen binär angegeben werden.
Für die Zuweisung von Schlüsselworten, zum Beispiel *NOT-SPECIFIED und *NONE, sind die Werte zu verwenden, die in den entsprechenden Strukturstufe-88-Erklärungen festgelegt sind.
Beschreibung der Datenfelder
Die Parameter der FT-NDEL-LIST haben dieselben Namen und Funktionen wie die entsprechenden Operanden des DELETE-REMOTE-FILE-Kommandos.
Mit dem Parameter USER-DEF-ADM-ATTR bestimmen Sie, wie die Angabe für USER-DEF-ADMISSION interpretiert wird. Mit dem Wert GRAPHIC wird die Angabe für USER-DEF-ADMISSION als abdruckbare Zeichen interpretiert und bei einer Übertragung auf ein System, das nicht EBCDIC benutzt, konvertiert. Mit dem Wert OCTET wird die Angabe für USER-DEF-ADMISSION als Binärinformation interpretiert und nicht konvertiert.
Beispiel NDEL
****************************************************************
* *
* BEISPIEL: *
* *
* /DELETE-REMOTE-FILE PARTNER=VAR001,FILE-NAME=REMOTEFILE,- *
* / TRANS=(USID,ACCOUNT,'PASSWORD') *
* *
* AUS EINEM COBOL-PROGRAMM *
* *
****************************************************************
IDENTIFICATION DIVISION.
PROGRAM-ID. TESTNDEL.
*
ENVIRONMENT DIVISION.
*
CONFIGURATION SECTION.
SPECIAL-NAMES.
TERMINAL IS TERM.
*
DATA DIVISION.
WORKING-STORAGE SECTION.
77 MAIN-RCODE-STRING PIC -ZZZZ9.
77 SUB-RCODE-STRING PIC -ZZZZ9.
COPY FTNDEL OF FTLIB.
COPY FTRETC OF FTLIB.
*
PROCEDURE DIVISION.
STEUER SECTION.
ST-01.
*
*PARAMETER-VERSORGEN.
MOVE LOW-VALUE TO USER-PARAMETERS.
MOVE "VAR001" TO PARTNER-NAME.
MOVE "REMOTEFILE" TO FILE-NAME.
MOVE "USERID" TO USER-ID.
MOVE "ACCOUNT" TO ACCOUNT.
MOVE "'PASSWORD'" TO PASSWORD.
*
*NDEL-AUFRUFEN.
CALL "NDEL" USING FT-NDEL-LIST FT-RETURN-INFO.
*
*ERGEBNIS-BEHANDLUNG.
IF OKAY IN MAIN-RETURN-CODE
THEN
DISPLAY "NDEL OKAY" UPON TERM
ELSE
MOVE MAIN-RETURN-CODE TO MAIN-RCODE-STRING
MOVE SUB-RETURN-CODE TO SUB-RCODE-STRING
DISPLAY "NDEL ABGELEHNT" UPON TERM
DISPLAY "MAIN-RETURN-CODE: " MAIN-RCODE-STRING
" SUB-RETURN-CODE: " SUB-RCODE-STRING
UPON TERM.
ST-99.
STOP RUN.