Mit dem Aufruf CALL "NMOD"... können Sie Attribute einer Datei in einem FT-Partnersystem ändern. Der Funktionsumfang entspricht dem Kommando MODIFY-REMOTE-FILE-ATTRIBUTES.
Aufruf
Die Funktion können Sie wie folgt aufrufen:
CALL "NMOD" USING FT-NMOD-LIST FT-RETURN-INFO.
FT-NMOD-LIST
Der Bereich FT-NMOD-LIST beschreibt die Parameterliste für den NMOD-Aufruf. FT-NMOD-LIST muss in der WORKING-STORAGE SECTION definiert sein und kann mit der Anweisung
COPY FTNMOD OF linkname.
dorthin kopiert werden.
Vor dem ersten NMOD-Aufruf sollten die Parameterfelder mit der Anweisung
MOVE LOW-VALUE TO USER-PARAMETERS IN FT-NMOD-LIST.
gelöscht werden.
Vor einem weiteren NMOD-Aufruf müssen Sie die gewünschten Felder ausfüllen. Soll ein Parameter nicht angegeben werden bzw. auf den Standardwert Bezug genommen werden, so muss diesem Feld der Wert LOW-VALUE zugewiesen werden.
FT-NMOD-LIST ist folgendermaßen definiert:
01 FT-NMOD-LIST.
*
02 FILLER PIC X(4) VALUE "1000".
*
02 USER-PARAMETERS.
*
05 PARTNER-NAME PIC X(200).
*
05 FILE-NAME PIC X(512).
88 NOT-SPECIFIED VALUE LOW-VALUE.
*
05 FILE-PASSWORD PIC X(64).
88 NONE VALUE LOW-VALUE.
05 FILE-PASSWD-ATTR PIC X(1).
88 GRAPHIC VALUE LOW-VALUE.
88 OCTET VALUE "0".
*
05 USER-DEF-ADMISSION PIC X(67).
88 NONE VALUE LOW-VALUE.
05 USER-DEF-ADM-ATTR PIC X(1).
88 GRAPHIC VALUE LOW-VALUE.
88 OCTET VALUE "O".
05 TRANSFER-ADMISSION.
10 USER-ID PIC X(67).
10 ACCOUNT PIC X(64).
88 NONE VALUE LOW-VALUE.
10 PASSWORD PIC X(64).
88 NONE VALUE LOW-VALUE.
05 USER-PASSWD-ATTR PIC X(1).
88 GRAPHIC VALUE LOW-VALUE.
88 OCTET VALUE "0".
*
05 NEW-NAME PIC X(512).
88 SAME-NAME VALUE LOW-VALUE.
*
05 FILE-AVAILABILITY PIC X(1).
88 UNCHANGED VALUE LOW-VALUE.
88 IMMEDIATE VALUE "I".
88 DEFERRED VALUE "D".
*
05 STORAGE-ACCOUNT PIC X(40).
88 UNCHANGED VALUE LOW-VALUE.
*
05 FUTURE-FILE-SIZE PIC X(4).
88 UNCHANGED VALUE LOW-VALUE.
*
05 ACCESS-MODE PIC X(1).
88 UNCHANGED VALUE LOW-VALUE.
88 REPLACE-ALL-BY VALUE "R".
88 ADD-PAR VALUE "A".
05 READ-FILE PIC X(1).
88 NO-VALUE VALUE LOW-VALUE.
88 NO-PAR VALUE "N".
88 YES VALUE "Y".
05 INSERT-DATA-UNIT PIC X(1).
88 NO-VALUE VALUE LOW-VALUE.
88 NO-PAR VALUE "N".
88 YES VALUE "Y".
05 REPLACE-FILE PIC X(1).
88 NO-VALUE VALUE LOW-VALUE.
88 NO-PAR VALUE "N".
88 YES VALUE "Y".
05 EXTEND-FILE PIC X(1).
88 NO-VALUE VALUE LOW-VALUE.
88 NO-PAR VALUE "N".
88 YES VALUE "Y".
05 ERASE-DATA-UNIT PIC X(1).
88 NO-VALUE VALUE LOW-VALUE.
88 NO-PAR VALUE "N".
88 YES VALUE "Y".
05 READ-ATTRIBUTES PIC X(1).
88 NO-VALUE VALUE LOW-VALUE.
88 NO-PAR VALUE "N".
88 YES VALUE "Y".
05 CHANGE-ATTRIBUTES PIC X(1).
88 NO-VALUE VALUE LOW-VALUE.
88 NO-PAR VALUE "N".
88 YES VALUE "Y".
05 DELETE-FILE PIC X(1).
88 NO-VALUE VALUE LOW-VALUE.
88 NO-PAR VALUE "N".
88 YES VALUE "Y".
*
05 LEGAL-QUALIFICATION PIC X(80).
88 UNCHANGED VALUE LOW-VALUE.
Die am Anfang der Struktur stehende Versionsangabe dient zur Identifikation des COPY-Elements und darf vom Benutzer nicht überschrieben werden.
Durch einen NMOD-Aufruf werden keine Werte in der Struktur FT-NMOD-LIST geändert.
Die Felder sind linksbündig zu beschreiben und rechtsbündig mit Leerzeichen aufzufüllen (Standard bei der COBOL-MOVE-Anweisung für Zeichenketten).
Felder, die keine Angaben enthalten sollen, sind mit der Zuweisung LOW-VALUE zu kennzeichnen.
Bei Nichtangabe eines Parameters werden wie beim Kommando MODIFY-REMOTE-FILE-ATTRIBUTES die Standardwerte abgesetzt.
Alle weiteren Werte, die an der Kommandoschnittstelle in Hochkommata eingeschlossen sein müssen, haben diese Hochkommata an der Programmschnittstelle nicht.
Kennwörter mit Integer-Wert müssen binär angegeben werden.
Für die Zuweisung von Schlüsselworten, zum Beispiel *NOT-SPECIFIED und *YES, sind die Werte zu verwenden, die in den entsprechenden Strukturstufe-88-Erklärungen festgelegt sind.
Beschreibung der Datenfelder
Die Parameter der FT-NMOD-LIST haben dieselben Namen und Funktionen wie die entsprechenden Operanden des Kommandos MODIFY-REMOTE-FILE-ATTRIBUTES. Bitte beachten Sie daher die entsprechende Kommandobeschreibung im Handbuch "openFT (BS2000) - Kommandoschnittstelle".
Mit dem Parameter USER-DEF-ADM-ATTR bestimmen Sie, wie die Angabe für USER-DEF-ADMISSION interpretiert wird. Mit dem Wert GRAPHIC wird die Angabe für USER-DEF-ADMISSION als abdruckbare Zeichen interpretiert und bei einer Übertragung auf ein System, das nicht EBCDIC benutzt, konvertiert. Mit dem Wert OCTET wird die Angabe für USER-DEF-ADMISSION als Binärinformation interpretiert und nicht konvertiert.
Beispiel NMOD
*******************************************************************
* BEISPIEL: *
* *
* /MODIFY-REMOTE-FILE-ATTRIBUTES - *
* / PARTNER=VAR001,FILE-NAME=OLDFILE,NEW-NAME=NEWFILE,- *
* / TRANS=(USID,ACCOUNT,'PASSWORD') *
* *
* AUS EINEM COBOL-PROGRAMM *
*******************************************************************
IDENTIFICATION DIVISION.
PROGRAM-ID. TESTNMOD.
*
ENVIRONMENT DIVISION.
*
CONFIGURATION SECTION.
SPECIAL-NAMES.
TERMINAL IS TERM.
*
DATA DIVISION.
WORKING-STORAGE SECTION.
77 MAIN-RCODE-STRING PIC -ZZZZ9.
77 SUB-RCODE-STRING PIC -ZZZZ9.
COPY FTNMOD OF FTLIB.
COPY FTRETC OF FTLIB.
*
PROCEDURE DIVISION.
STEUER SECTION.
ST-01.
*
*PARAMETER-VERSORGEN.
MOVE LOW-VALUE TO USER-PARAMETERS.
MOVE "VAR001" TO PARTNER-NAME.
MOVE "OLDFILE" TO FILE-NAME.
MOVE "NEWFILE" TO NEW-NAME.
MOVE "USERID" TO USER-ID.
MOVE "ACCOUNT" TO ACCOUNT.
MOVE "'PASSWORD'" TO PASSWORD.
*
*NMOD-AUFRUFEN.
CALL "NMOD" USING FT-NMOD-LIST FT-RETURN-INFO.
*
*ERGEBNIS-BEHANDLUNG.
IF OKAY IN MAIN-RETURN-CODE
THEN
DISPLAY "NMOD OKAY" UPON TERM
ELSE
MOVE MAIN-RETURN-CODE TO MAIN-RCODE-STRING
MOVE SUB-RETURN-CODE TO SUB-RCODE-STRING
DISPLAY "NMOD ABGELEHNT" UPON TERM
DISPLAY "MAIN-RETURN-CODE: " MAIN-RCODE-STRING
" SUB-RETURN-CODE: " SUB-RCODE-STRING
UPON TERM.
ST-99.
STOP RUN.