Mit dem Aufruf CALL "NSHOW"... können Sie sich die Attribute einer Datei bzw. eines Dateiverzeichnisses anzeigen lassen, die zu einer Datei bzw. zu einem Dateiverzeichnis in einem FT-Partnersystem vorliegen. Der Funktionsumfang entspricht dem Kommando SHOW-REMOTE-FILE-ATTRIBUTES.
Für die Ausgabe der Attribute kann der Benutzer drei Varianten wählen:
Anzeige des Namens der Datei,
Anzeige einer Standardauswahl,
Anzeige aller zurückgelieferten Attribute einer Datei.
Die Ausgabe kann auf Bildschirm oder in eine Datei erfolgen.
Aufruf
Die Funktion können Sie wie folgt aufrufen:
CALL "NSHOW" USING FT-NSHOW-LIST FT-RETURN-INFO.
FT-NSHOW-LIST
Der Bereich FT-NSHOW-LIST beschreibt die Parameterliste für den NSHOW-Aufruf.FT-NSHOW-LIST muss in der WORKING-STORAGE SECTION definiert sein und kann mit der Anweisung
COPY FTNSHOW OF linkname.
dorthin kopiert werden.
Vor dem ersten NSHOW-Aufruf sollten die Parameterfelder mit der Anweisung
MOVE LOW-VALUE TO USER-PARAMETERS IN FT-NSHOW-LIST.
gelöscht werden.
Vor einem weiteren NSHOW-Aufruf müssen Sie die gewünschten Felder ausfüllen. Soll ein Parameter nicht angegeben werden bzw. auf den Standardwert Bezug genommen werden, so muss diesem Feld der Wert LOW-VALUE zugewiesen werden.
FT-NSHOW-LIST ist folgendermaßen definiert:
01 FT-NSHOW-LIST.
*
02 FILLER PIC X(4) VALUE "1000".
*
02 USER-PARAMETERS.
*
05 PARTNER-NAME PIC X(200).
*
05 FILE-NAME PIC X(512).
88 NOT-SPECIFIED VALUE LOW-VALUE.
05 DIRECTORY PIC X(512).
88 NOT-SPECIFIED VALUE LOW-VALUE.
*
05 FILE-PASSWORD PIC X(64).
88 NONE VALUE LOW-VALUE.
05 FILE-PASSWD-ATTR PIC X(1).
88 GRAPHIC VALUE LOW-VALUE.
88 OCTET VALUE "O".
*
05 USER-DEF-ADMISSION PIC X(67).
88 NONE VALUE LOW-VALUE.
05 USER-DEF-ADM-ATTR PIC X(1).
88 GRAPHIC VALUE LOW-VALUE.
88 OCTET VALUE "O".
05 TRANSFER-ADMISSION.
10 USER-ID PIC X(67).
10 ACCOUNT PIC X(64).
88 NONE VALUE LOW-VALUE.
10 PASSWORD PIC X(64).
88 NONE VALUE LOW-VALUE.
05 USER-PASSWD-ATTR PIC X(1).
88 GRAPHIC VALUE LOW-VALUE.
88 OCTET VALUE "O".
*
05 INFORMATION PIC X(1).
88 STD VALUE LOW-VALUE.
88 ALL-ATTRIBUTES VALUE "A".
88 ONLY-NAMES VALUE "O".
*
05 OUTPUT-PAR PIC X(1).
88 SYSOUT VALUE LOW-VALUE.
88 SYSLST VALUE "L".
88 SYSOUTCSV VALUE "O".
88 SYSLSTCSV VALUE "C".
Die am Anfang der Struktur stehende Versionsangabe dient zur Identifikation des COPY-Elements und darf vom Benutzer nicht überschrieben werden.
Durch einen NSHOW-Aufruf werden keine Werte in der Struktur FT-NSHOW-LIST geändert.
Die Felder sind linksbündig zu beschreiben und rechtsbündig mit Leerzeichen aufzufüllen (Standard bei der COBOL-MOVE-Anweisung für Zeichenketten).
Felder, die keine Angaben enthalten sollen, sind mit der Zuweisung LOW-VALUE zu kennzeichnen.
Bei Nichtangabe eines Parameters werden wie beim Kommando SHOW-REMOTE-FILE-ATTRIBUTES die Standardwerte abgesetzt.
Alle weiteren Werte, die an der Kommandoschnittstelle in Hochkommata eingeschlossen sein müssen, haben diese Hochkommata an der Programmschnittstelle nicht.
Kennwörter mit Integer-Wert müssen binär angegeben werden.
Für die Zuweisung von Schlüsselworten, zum Beispiel *NOT-SPECIFIED und *SYSLST, sind die Werte zu verwenden, die in den entsprechenden Strukturstufe-88-Erklärungen festgelegt sind.
Beschreibung der Datenfelder
Die Parameter der FT-NSHOW-LIST haben dieselben Namen und Funktionen wie die entsprechenden Operanden des Kommandos SHOW-REMOTE-FILE-ATTRIBUTES. Bitte beachten Sie daher die entsprechende Kommandobeschreibung im Handbuch "openFT (BS2000) - Kommandoschnittstelle".
Mit dem Parameter USER-DEF-ADM-ATTR bestimmen Sie, wie die Angabe für USER-DEF-ADMISSION interpretiert wird. Mit dem Wert GRAPHIC wird die Angabe für USER-DEF-ADMISSION als abdruckbare Zeichen interpretiert und bei einer Übertragung auf ein System, das nicht EBCDIC benutzt, konvertiert. Mit dem Wert OCTET wird die Angabe für USER-DEF-ADMISSION als Binärinformation interpretiert und nicht konvertiert.
Beispiel NSHOW
*******************************************************************
* BEISPIEL: *
* *
* /SHOW-REMOTE-FILE-ATTRIBUTES - *
* / PARTNER=VAR001,FILE-NAME=REMOTEFILE,- *
* / TRANS=(USID,ACCOUNT,'PASSWORD'),- *
* / INFORMATION=*ALL-ATTRIBUTES *
* *
* AUS EINEM COBOL-PROGRAMM *
*******************************************************************
IDENTIFICATION DIVISION.
PROGRAM-ID. TESTNSHOW.
*
ENVIRONMENT DIVISION.
*
CONFIGURATION SECTION.
SPECIAL-NAMES.
TERMINAL IS TERM.
*
DATA DIVISION.
WORKING-STORAGE SECTION.
77 MAIN-RCODE-STRING PIC -ZZZZ9.
77 SUB-RCODE-STRING PIC -ZZZZ9.
COPY FTNSHOW OF FTLIB.
COPY FTRETC OF FTLIB.
*
PROCEDURE DIVISION.
STEUER SECTION.
ST-01.
*
*PARAMETER-VERSORGEN.
MOVE LOW-VALUE TO USER-PARAMETERS.
MOVE "VAR001" TO PARTNER-NAME.
MOVE "REMOTEFILE" TO FILE-NAME.
MOVE "USERID" TO USER-ID.
MOVE "ACCOUNT" TO ACCOUNT.
MOVE "'PASSWORD'" TO PASSWORD.
SET ALL-ATTRIBUTES IN INFORMATION TO TRUE.
*
*NSHOW-AUFRUFEN.
CALL "NSHOW" USING FT-NSHOW-LIST FT-RETURN-INFO.
STOP RUN.
*
*ERGEBNIS-BEHANDLUNG.
IF OKAY IN MAIN-RETURN-CODE
THEN
DISPLAY "NSHOW OKAY" UPON TERM
ELSE
MOVE MAIN-RETURN-CODE TO MAIN-RCODE-STRING
MOVE SUB-RETURN-CODE TO SUB-RCODE-STRING
DISPLAY "NSHOW ABGELEHNT" UPON TERM
DISPLAY "MAIN-RETURN-CODE: " MAIN-RCODE-STRING
" SUB-RETURN-CODE: " SUB-RCODE-STRING
UPON TERM.
ST-99.
STOP RUN.