openFT V12.1C (de)

&pagelevel(4)&pagelevel

In diesem Abschnitt finden Sie Beispiele für Anwendungen des TRANSFER-FILEKommandos.

TRANSFER-FILEKommando für openFT nur mit Pflichtoperanden

Das Kommando TRANSFER-FILE kann unter den in Abschnitt „Kürzeste Form des Kommandos“ beschriebenen Voraussetzungen nur mit den Pflichtoperanden eingegeben werden.

In dem folgenden Beispiel soll die Datei DATA vom lokalen Rechner in den Partner-Rechner VAR001 übertragen werden.
Das Kommando wird in der empfohlenen Kurzform angegeben.

/TFF TO,VAR001,(DATA)
% FTR0000 Auftrag (&00) angenommen
/

Die Langform des Kommandos lautet:

/TRANSFER-FILE TRANSFER-DIRECTION = TO, -/ PARTNER = VAR001, -/ LOCAL-PARAMETER = (FILE-NAME = DATA)

Wenn der Benutzer unter dieser Kennung weiter im Teilnehmerbetrieb arbeitet, erhält er nach erfolgreicher Dateiübertragung asynchron die Meldung:

%MESS % FTR0005 (&01'')Auftrag (&00). Datei '(&02)' uebertragen

Übertragen einer kennwortgeschützten Datei, die im fernen System unter einer anderen Benutzerkennung katalogisiert ist

Die Datei LISTE ist im Rechner VAR002 unter der Kennung VERSAND gespeichert und mit dem Kennwort C’XX’ geschützt. Die Kennung VERSAND hat die
Abrechnungsnummer VERS002 und das Passwort PASS1492 .

Im Folgenden sind sowohl die Kurzform als auch die Langform des Kommandos dargestellt, mit der die Datei LISTE in das lokale System übertragen und dort in der noch nicht eingerichteten Datei LISTE.002 abgespeichert wird. Gibt es diese Datei schon, so soll die Datei nicht übertragen werden.

Empfohlene Kurzform des Kommandos:

/TFF FROM,VAR002, - / (LISTE.002), -/ (LISTE,'XX',TRANS-AD = (VERSAND,VERS002,'PASS1492')),WRITE = NEW% FTR0000 Auftrag (&00) angenommen

Langform des Kommandos:

/TRANSFER-FILE TRANSFER-DIRECTION = FROM-PARTNER,PARTNER = VAR002, - LOCAL-PARAMETER = (FILE-NAME = LISTE.002), -/ REMOTE-PARAMETER = *BS2000(FILE-NAME = LISTE,PASSWORD = C'XX', -/ TRANSFER-ADMISSION = (USER-IDENTIFICATION = VERSAND, - / ACCOUNT = VERS002,PASSWORD = 'PASS1492')),WRITE-MODE = *NEW-FILE% FTR0000 Auftrag (&00) angenommen

Einsammeln von Dateien

Eine Zentrale muss an jedem Ersten im Monat die Monatsberichte ihrer 5 Zweigstellen einsammeln. Diese Monatsberichte sind in jeder Zweigstelle druckfertig aufbereitet in einer Datei mit dem Namen BERICHT.monat enthalten und sollen in der Zentrale jeweils in einer Datei mit dem Namen BERICHT.monat.zweigstelle abgespeichert und dort ausgedruckt werden. Zum Abholen der Dateien wurde auf jedem Zweigstellenrechner die Zugangsberechtigung GETBERICHT eingerichtet.

Die Übertragung dieser Dateien erfolgt mit der folgenden Prozedur:

/BEGIN-PROCEDURE LOGGING=NO,PARAMETERS=YES(PROCEDURE-PARAMETERS= -

/(&MONAT=),ESCAPE-CHARACTER='&')

/REMARK FUER &MONAT BITTE DEN VERGANGENEN MONAT ANGEBEN !

/TRANS-FILE FROM,FILIALE1, -
/(BERICHT.&MONAT..FILIALE1, -

/SUCC='/PRINT-FILE FILE-NAME=BERICHT.&MONAT..FILIALE1, -

/SPOOLOUT-NAME=FILIALE1,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)'), -
/(BERICHT.&MONAT,TRANS-AD=GETBERICHT)

/TRANS-FILE FROM,FILIALE2, -

/(BERICHT.&MONAT..FILIALE2, -
/SUCC='/PRINT-FILE FILE-NAME=BERICHT.&MONAT..FILIALE2, -

/SPOOLOUT-NAME=FILIALE2,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)'), -

/(BERICHT.&MONAT,TRANS-AD=GETBERICHT)

/TRANS-FILE FROM,FILIALE3, -

/(BERICHT.&MONAT..FILIALE3, -

/SUCC='/PRINT-FILE FILE-NAME=BERICHT.&MONAT..FILIALE3, -
/SPOOLOUT-NAME=FILIALE3,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)'), -

/(BERICHT.&MONAT,TRANS-AD=GETBERICHT)

/TRANS-FILE FROM,FILIALE4, -
/(BERICHT.&MONAT..FILIALE4, -

/SUCC='/PRINT-FILE FILE-NAME=BERICHT.&MONAT..FILIALE4, -

/SPOOLOUT-NAME=FILIALE4,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)'), -
/(BERICHT.&MONAT,TRANS-AD=GETBERICHT)

/TRANS-FILE FROM,FILIALE5, -

/(BERICHT.&MONAT..FILIALE5, -
/SUCC='/PRINT-FILE FILE-NAME=BERICHT.&MONAT..FILIALE5, -

/SPOOLOUT-NAME=FILIALE5,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)'), -

/(BERICHT.&MONAT,TRANS-AD=GETBERICHT)

/END-PROCEDURE

Diese CALL-PROCEDURE-Prozedur (Name: DO.MONAT) wird wie folgt aufgerufen:

/CALL-PROCEDURE DO.MONAT

%/REMARK FUER &MONAT BITTE DEN VERGANGENEN MONAT ANGEBEN !

%&MONAT=november

% FTR0000 Auftrag 194577 angenommen

% FTR0000 Auftrag 194987 angenommen

% FTR0000 Auftrag 195442 angenommen
% FTR0000 Auftrag 196099 angenommen

% FTR0000 Auftrag 196583 angenommen

/

Verteilen von Dateien

Eine Zentrale verteilt Richtlinien an ihre fünf Zweigstellen.
Sie lässt die Richtlinien gleich in ihren Zweigstellen ausdrucken. Alle beteiligten Benutzerkennungen, in der Zentrale sowie in den Zweigstellen, heißen ZENTRALE mit der Abrechnungsnummer ZENTR01 und Kennwort C ́ZEN ́.

Zum Verteilen der Richtlinien benutzt die Zentrale die folgende ENTER-JOB-Prozedur: :

/LOGON

/TRANS-FILE TO,FILIALE1, -

/(RICHTLINIE,TRANS-AD=(ZENTRALE,ZENTR01,C'ZEN')), -

/(SUCC='/PRINT-FILE FILE-NAME=RICHTLINIE,SPOOLOUT-NAME=WICHTIG, -
/LAYOUT-CONTROL=(CONTROL-CHARACTER=EBCDIC)')

/TRANS-FILE TO,FILIALE2, -

/(RICHTLINIE,TRANS-AD=(ZENTRALE,ZENTR01,C'ZEN')), -
/(SUCC='/PRINT-FILE FILE-NAME=RICHTLINIE,SPOOLOUT-NAME=WICHTIG, -

/LAYOUT-CONTROL=(CONTROL-CHARACTER=EBCDIC)')

/TRANS-FILE TO,FILIALE3, -
/(RICHTLINIE,TRANS-AD=(ZENTRALE,ZENTR01,C'ZEN')), -

/(SUCC='/PRINT-FILE FILE-NAME=RICHTLINIE,SPOOLOUT-NAME=WICHTIG, -

/LAYOUT-CONTROL=(CONTROL-CHARACTER=EBCDIC)')

/TRANS-FILE TO,FILIALE4, -

/(FILE=RICHTLINIE,TRANS-AD=(ZENTRALE,ZENTR01,C'ZEN')), -

/(SUCC='/PRINT-FILE FILE-NAME=RICHTLINIE,SPOOLOUT-NAME=WICHTIG, -
/LAYOUT-CONTROL=(CONTROL-CHARACTER=EBCDIC)')

/TRANS-FILE TRANS=TO,PARTNER=FILIALE5, -

/(RICHTLINIE,TRANS-AD=(ZENTRALE,ZENTR01,C'ZEN')), -
/(SUCC='/PRINT-FILE FILE-NAME=RICHTLINIE,SPOOLOUT-NAME=WICHTIG, -

/LAYOUT-CONTROL=(CONTROL-CHARACTER=EBCDIC)')

/LOGOFF

Diese ENTER-JOB-Prozedur (Name: ENTER.RICHTLINIE) wird wie folgt aufgerufen:

/.ZENTRALE ENTER-JOB ENTER.RICHTLINIE,TIME=99

% JMS0066 JOB ACCEPTED. TSN=2083

Mit dem BS2000-Kommando SHOW-USER-STATUS kann man den Ablauf dieses ENTER-Prozesses und der Dateiübertragungen verfolgen:

/SHOW-USER-STATUS

NAME TSN TYPE PRI CPU-USED CPU-MAX ACCOUNT#

ZENTRALE 2083 1 210 0.0 99 ZENTR01
GP46518 2065 3 DIA 210 0.4595 32767 ZENTR01

/SHOW-USER-STATUS

NAME TSN TYPE PRI CPU-USED CPU-MAX ACCOUNT#
OPENFT 2088 1 210 0.0 1 ZENTR01

GP46518 2065 3 DIA 210 0.6868 32767 ZENTR01

NAME TSN TYPE PRI SIZE COPIES CPU-USED
ZENTRALE 2083 4 PR 210 2 0

/SHOW-USER-STATUS

NAME TSN TYPE PRI CPU-USED CPU-MAX ACCOUNT#
GP46518 2065 3 DIA 210 0.7957 32767 ZENTR01

OPENFT 2099 2 BAT 210 0.0938 1 ZENTR01

OPENFT 2100 2 BAT 210 0.0548 1 ZENTR01
NAME TSN TYPE PRI SIZE COPIES CPU-USED

ZENTRALE 2083 4 PR 210 2 0

OPENFT 2091 4 PR 210 1 0

OPENFT 2096 4 PR 210 1 0
OPENFT 2097 4 PR 210 1 0

/SHOW-USER-STATUS

NAME TSN TYPE PRI CPU-USED CPU-MAX ACCOUNT#
GP46518 2065 3 DIA 210 0.8545 32767 ZENTR01

NAME TSN TYPE PRI SIZE COPIES CPU-USED

ZENTRALE 2083 4 PR 210 2 0
OPENFT 2091 4 PR 210 1 0

OPENFT 2096 4 PR 210 1 0

OPENFT 2097 4 PR 210 1 0
OPENFT 2101 4 PR 210 1 0

OPENFT 2102 4 PR 210 1 0

Jobübertragung und Jobverarbeitung

Um den zentralen Verarbeitungsrechner zu entlasten, soll ein Assembler-Programm im Verarbeitungsrechner einer Filiale übersetzt werden. Dazu wird das Programm innerhalb einer CALL-PROCEDURE-Prozedur-Datei übersetzt, die als
Folgeverarbeitung gestartet wird. Nach Abarbeiten des FT-Auftrags wird das übersetzte Programm in einer Modulbibliothek abgespeichert. Die Modulbibliothek soll anschließend zurück in den zentralen Verarbeitungsrechner übertragen werden.

Die CALL-PROCEDURE-Prozedur DO.JOB sieht z.B. wie folgt aus:

/BEGIN-PROCEDURE LOGGING=COMMANDS

/DELETE-FILE FILE-NAME=*

/ASSIGN-SYSDTA TO-FILE=*SYSCMD

/START-ASSEMBH

.

. Programm, das übersetzt werden soll!
.

/START-LMS

//OPEN-LIB ZENTRALE.MODLIB,MODE=*UPDATE

//ADD-ELEMENT FROM-FILE=*OMF,TO-ELEMENT=*LIB-ELEM(TYPE=R)

//END

/ASSIGN-SYSDTA TO-FILE=*PRIMARY

/TRANS-FILE TRANS=TO,PARTNER=ZENTRALE,LOC=(FILE-NAME=ZENTRALE.MODLIB, -
/ TRANS-AD=(ZENTRALE,ZENTR01,C'ZEN'))

/END-PROCEDURE

Diese CALL-PROCEDURE-Prozedur wird mit dem folgenden Kommando zum Rechner in der Zweigstelle 1 übertragen und dort gestartet. Der Auftrag soll in der Zentrale von der Jobvariablen XYZ überwacht werden.

/TRANS-FILE TO,FILIALE1,(DO.JOB,MONJV=XYZ),REM= -
/ (TRANS-AD=(ZENTRALE,ZENTR01,C'ZEN'),SUCC='/CALL-PROCEDURE DO.JOB')

% FTR0000 Auftrag 194572 angenommen

Aneinanderketten von Dateien

Eine Zentrale sammelt SAM-Dateien (z.B. Transaktionsdateien) aus ihren 3 Zweigstellen ein. Die Dateien sollen aneinandergekettet und erst dann verarbeitet werden, wenn alle einzusammelnden Dateien übertragen wurden. Die Dateien haben im Beispiel die Dateinamen SAM.DATEI und sollen in der Datei SAM.GESAMT hintereinander abgespeichert werden.
Die einzusammelnden Dateien sind kennwortgeschützt. Die Kennungen sind nicht kennwortgeschützt (das Betriebssystem BS2000 wurde mit dem Systemparameter SSMCOPT=Y generiert).

Die Dateien werden mit der folgenden CALL-PROCEDURE-Prozedur (Name: DO.KETTE) übertragen:

/BEGIN-PROCEDURE LOGGING=COMMANDS

/TRANS-FILE TRANS=FROM,PARTNER=FILIALE1,WRITE=EXT, -

/REM=(FILE-NAME=SAM.DATEI,PASS='FIL1',TRANS=GETFILES), -
/LOC=(FILE-NAME=SAM.GESAMT, -

/SUCC='/TRANS-FILE TRANS=FROM,PARTNER=FILIALE2,WRITE=EXT, -

/REM=(FILE-NAME=SAM.DATEI,PASS=''FIL2'',TRANS=GETFILES), -
/LOC=(FILE-NAME=SAM.GESAMT, -

/SUCC=''/TRANS-FILE TRANS=FROM,PARTNER=FILIALE3,WRITE=EXT, -

/LOC=(FILE-NAME=SAM.GESAMT), -
/REM=(FILE-NAME=SAM.DATEI,PASS=''''FIL3'''',TRANS=GETFILES)'')')

/END-PROCEDURE

Die Prozedur rufen Sie wie folgt auf:

/CALL-PROCEDURE DO.KETTE

%/BEGIN-PROCEDURE LOGGING=COMMANDS

%/TRANS-FILE TRANS=FROM,PARTNER=FILIALE1,WRITE=EXT,

REM=(FILE-NAME=SAM.DATEI,PASS='FIL1',TRANS=GETFILES),

LOC=(FILE-NAME=SAM.GESAMT,SUCC='/TRANS-FILE TRANS=FROM,

PARTNER=FILIALE2,WRITE=EXT,REM=(FILE-NAME=SAM.DATEI,

PASS=''FIL2'',TRANS=GETFILES),

LOC=(FILE-NAME=SAM.GESAMT),

SUCC=''/TRANS-FILE TRANS=FROM,PARTNER=FILIALE3,WRITE=EXT,

LOC=(FILE-NAME=SAM.GESAMT),

REM=(FILE-NAME=SAM.DATEI,PASS=''''FIL3'''',TRANS=GETFILES)'')')

% FTR0000 Auftrag 164572 angenommen

%/END-PROCEDURE

Dateiübertragung zwischen openFT (BS2000) und einem anderen FT-System

Die Datei DATEI soll mit openFT (BS2000) in ein anderes System übertragen werden. In dem anderen System (SYS) gilt die Benutzer-Identifikation BROOKLYN mit dem Kennwort 20000. Die Datei soll hier den Namen d/a/t/e/i haben. Es wird die Kurzform des Kommandos verwendet:

/TRANS-FILE TO,SYS,(DATEI), -
/*ANY('d/a/t/e/i',TRANS-AD=('BROOKLYN',,'20000'))

% FTR0000 Auftrag 165572 angenommen

Dateiübertragung von POSIX-Dateien zwischen zwei openFT (BS2000)-Systemen
Die POSIX-Datei datei soll mit openFT in den BS2000-Rechner HOST12 in das Home-Directory /home/JIMMY übertragen werden. Im HOST12 gilt die Benutzer-Identifikation JIMMY mit der Abrechnungsnummer 12345678 und dem Kennwort 20000. Da die Benutzerkennung für das ferne System angegeben wird, hätte die Angabe des relativen Pfadnamens ausgereicht. Es wird die Kurzform des Kommandos verwendet:
/TRANS-FILE TO,HOST12,(‘./datei‘), -
/(c‘/home/JIMMY/datei‘,TRANS-ADM=(JIMMY,12345678,'20000'))
% FTR0000 Auftrag 165581 angenommen
Kommando mit *POSIX:
/TRANS-FILE TO,HOST12,(*POSIX(datei)), --
/(*POS(/home/JIMMY/datei),TRANS-ADM=(JIMMY,12345678,'20000'))
% FTR0000 Auftrag 165581 angenommen

Dateiübertragung zu

z/OS-Systemen

Die Datei DATEI soll von einem BS2000-Rechner in das z/OS-System IBM1 übertragen werden. Die Datei ist im lokalen System unter der Kennung ZENTRBS2 abgespeichert und hat das Datei-Kennwort C’ZZZZ’. Die Benutzerkennung hat die
Abrechnungsnummer ZENTR01 und ist mit dem Kennwort C’ZEN1’ geschützt. Im z/OS-System soll die Datei FILE heißen, das Kennwort FILE01 haben und unter der Benutzerkennung ZENMSP mit der Abrechnungsnummer ZENTRAL02 und dem Kennwort ZEN2 abgespeichert werden. Das Kommando wird in Kurzform eingegeben.

/TRANS-FILE TO,IBM1, -

/(DATEI,C'ZZZZ',TRANS-AD=(ZENTRBS2,ZENTR01,C'ZEN1')), -

/*MSP(FILE,FILE01,TRANS-AD=(ZENMSP,ZENTRAL02,ZEN2))

% FTR0000 Auftrag 143581 angenommen

Dateiübertragung mit openFT (Unix-Systeme)
Die Datei Leserpost soll vom Unix-System ALFRED in das lokale BS2000-System geholt werden. Die Datei ist im Rechner ALFRED unter der Kennung „drais“ mit dem Kennwort 144002 abgelegt und soll im lokalen System den Namen EILT.NICHT erhalten. Ein abgekürztes Kommando für diesen Auftrag lautet:
/TRANS-FILE FROM,ALFRED,(EILT.NICHT),*ANY('Leserpost', -
/TRANS-AD=('drais',,'144002'))
% FTR0000 Auftrag 122181 angenommen

Dateiübertragung mit anschließender Folgeverarbeitung ohne ein Protokoll über den

Verlauf der Folgeverarbeitung

Die Datei COBOL.LISTE soll vom Rechner COMPILER zum lokalen Rechner geholt und dort viermal ausgedruckt werden. Die Datei ist im Rechner COMPILER unter der Kennung COBOL mit der Abrechnungsnummer COBACC und dem Passwort PASSWORD abgelegt. Das Protokoll über den Ausdruck soll im Gutfall unterdrückt werden. Es gibt zwei Wege, diese Aufgabe zu lösen. Für den ersten, umständlicheren Weg wird zunächst im lokalen System die Prozedur FT.PRINT.PROC mit folgendem Inhalt angelegt:

/BEGIN-PROCEDURE PARAMETERS=YES(PROCEDURE-PARAMETERS= -

/(&DATEI=,&KOPIEN=0)

/PRINT-FILE FILE-NAME=&DATEI,REPEAT=&KOPIEN, -
/LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)

/END-PROCEDURE

Der eigentliche FT-Auftrag hat dann die Form

/TRANS-FILE FROM,COMPILER, -
/ (COBOL.LISTE, -

/ SUCC='/CALL-PROC FT.PRINT.PROC, -

/ (DATEI=COBOL.LISTE,KOPIEN=3)'), -

/ (TRANS-AD=(COBOL,COBACC,'PASSWORD’))

Auf die CALL-PROCEDURE-Prozedur kann aber auch verzichtet werden, wenn man im TRANS-FILE-Kommando für die Folgeverarbeitung ein Kommando angibt. Der FT-Auftrag hat dann die folgende Gestalt:

/TRANS-FILE FROM,COMPILER, -

/ (COBOL.LISTE,SUCC='/PRINT-FILE FILE-NAME=%FILENAME, -

/ REPEAT=3,LAYOUT-CONTROL=(CONTROL-CHARACTERS=EBCDIC)’), -
/ (TRANS-AD=(COBOL,COBACC,'PASSWORD’))

Übertragung einer Prozedurdatei mit anschließendem Ablauf der Prozedur als

Folgeverarbeitung sowie abschließendem Löschen der übertragenen Datei

Die Prozedurdatei PROC.JOB, die genau wie die Datei DO.JOB im Beispiel 5 aufgebaut ist, soll zum Rechner FILIALE1 übertragen werden und dort auf der Kennung ZENTRALE mit Abrechnungsnummer ZENTR01 und Kennwort ZEN ablaufen. Danach soll die Datei im fernen System wieder gelöscht werden.

Das nötige Kommando lautet:

/TRANSFER-FILE -

/ TRANSFER-DIRECTION=TO, -

/ PARTNER=FILIALE1, -
/ LOCAL-PARAMETER=(FILE-NAME=PROC.JOB), -

/ REMOTE-PARAMETER=(TRANSFER-ADMISSION=(ZENTRALE,ZENTR01,-

/ 'ZEN'),SUCCESS-PROCESSING='/CALL-PROCEDURE %FILENAME; -
/ /DELETE-FILE %FILENAME')

Eine mögliche Kurzform dieses Kommandos lautet:

/TFF TO,FILIALE1,(PROC.JOB),(TRANS-AD=(ZENTRALE,ZENTR01,'ZEN'),-

/ SUCC='/CALL-PROC %FILENAME;/DEL-FILE %FILENAME')

Dateiübertragung mit FTAC

Die Datei UMSATZ soll zum Rechner HUGOVOGT übertragen werden. Im Rechner HUGOVOGT wird openFT (BS2000) mit FTAC-Funktionalität für erweiterten Zugangs- und Zugriffsschutz eingesetzt. Für den FT-Auftrag wird im Rechner HUGOVOGT ein Berechtigungsprofil zur Verfügung gestellt.

Um mit diesem Berechtigungsprofil arbeiten zu können, muss die TRANSFER-ADMISSION 'FuerdenliebenStefan' als Zugangsberechtigung für den Rechner HUGOVOGT angegeben werden. Durch diese Angabe wird im Rechner HUGOVOGT direkt auf das Berechtigungsprofil zugegriffen. In diesem Berechtigungsprofil sind der Name, den die Datei im Rechner HUGOVOGT erhalten soll, und die Angaben für die Folgeverarbeitung (SUCCESS-PROCESSING und FAILURE-PROCESSING) in diesem Rechner fest vorgegeben. Für die PROCESSING-ADMISSION wurde der Wert *SAME festgelegt.

Im FT-Auftrag muss daher für den Dateinamen im fernen System der Wert *NOT-SPECIFIED stehen.
Die in diesem Beispiel für SUCCESS-PROCESSING und FAILURE-PROCESSING nötige Angabe *NONE entspricht dem Standardwert und kann daher weggelassen werden. Der Standardwert *SAME für die PROCESSING-ADMISSION wird von FTAC auch dann akzeptiert, wenn er im Berechtigungsprofil vorgegeben ist und kann daher ebenfalls weggelassen werden.

Das Kommando für die Dateiübertragung lautet dann in seiner Langform:

/TRANSFER-FILE -

/ TRANSFER-DIRECTION=TO, -

/ PARTNER=HUGOVOGT, -
/ LOCAL-PARAMETER=(FILE-NAME=UMSATZ), -

/ REMOTE-PARAMETER=*BS2000(FILE-NAME=*NOT-SPECIFIED, -

/ TRANSFER-ADMISSION='FuerdenliebenStefan')

Es geht natürlich auch kürzer:

/TFF TO,HUGOVOGT,(UMSATZ),(*NOT-SPEC,

/ TRANS-AD='FuerdenliebenStefan')

Zeitsteuerung bei der Dateiübertragung
Ein Anwender aus Orlando,
der fragte sich immer "quando?".
Er wollte um zehn
den File Transfer seh’n
und gab deshalb dieses Kommando:
/TRANSFER-FILE TO,ORLANDO2,(DATEI),START=(,10:00)
/ TRANS-ADMISSION='GruesseausOrlando'
Mit diesem Kommando wird die Datei DATEI zum Rechner ORLANDO2 übertragen und dort unter demselben Namen auf derselben Kennung wie im lokalen System abgelegt. Die Startzeit für diesen Auftrag wird auf frühestens 10 Uhr des Tages festgelegt, an dem der Auftrag abgegeben wird. Deshalb steht in der Klammer hinter START zunächst ein Komma. Es zeigt an, dass für den Operanden DATE, der als erster in der Klammer stehen müsste, der Standardwert *TODAY angenommen wird.
Da die Kennung durch Kennwort geschützt ist, muss die Transfer-Admission GruesseausOrlando angegeben werden. Sind die Kennungen nicht mit Kennwörtern geschützt, fällt dieser Operand aus dem Kommando heraus.

Lokale Vorverarbeitung zwischen zwei openFT (BS2000)-Systemen.

Es soll eine Auflistung der Namen von Dateien der lokalen Kennung in die ferne DateiSFA-FILE.LOKAL übertragen werden.

/TRANSFER-FILE -

/ TRANSFER-DIRECTION=*TO-PARTNER,PARTNER=BS2PART, -

/ LOCAL-PARAMETER=(FILE-NAME= -
/ C‘|/SHOW-FILE-ATTRIBUTES OUT=*SYSLST‘), -

/ REMOTE-PARAMETER=*BS2000(FILE-NAME=SFA-FILE.LOKAL, -

/ TRANSFER-ADMISSION=PROFBS2PART)
% FTR0000 Auftrag 172281 angenommen

Kurzform:

/TFF TO,BS2PART,('|/SHOW-FI-ATTR OUT=*SYSLST'), -

/ (SFA-FILE.LOKAL,,PROFBS2PART)

Ferne Vorverarbeitung zwischen zwei openFT (

BS2000)-Systemen.

Es soll eine Auflistung der FT-Partnersysteme im fernen System in die lokale Datei INFO.BS2PART übertragen werden.

Bei openFT Versionen <10 muss die ferne Kennung das Privileg FT-ADMINISTRATION besitzen, um Informationen über die Partnersysteme einholen zu können. Ist das nicht der Fall, wird der Auftrag mit der Meldung FTR2140 abgebrochen.

/TRANSFER-FILE -
/ TRANSFER-DIRECTION=*FROM-PARTNER, PARTNER=BS2PART, -

/ LOCAL-PARAMETER=(FILE-NAME=INFO.BS2PART), -

/ REMOTE-PARAMETER=*BS2000(FILE-NAME= -
/ C‘|/SH-FT-PART OUT=*SYSLST‘, -

/ TRANSFER-ADMISSION=PROFBS2PART)

% FTR0000 Auftrag 132281 angenommen

Kurzform:

/TFF FROM,BS2PART,(INFO.BS2PART), -

/ ('|/SH-FT-PART OUT=*SYSLST' -

/ ,,PROFBS2PART)

Kommando FTINFO als ferne Vorverarbeitung:

Es soll ermittelt werden, welche openFT-Version auf einem fernen Rechner installiert ist.

/TRANSFER-FILE -

/ TRANSFER-DIRECTION=*FROM-PARTNER, PARTNER=UNKNOWN, -

/ LOCAL-PARAMETER=(FILE-NAME=FTINFO.UNKNOWN), -
/ REMOTE-PARAMETER=*BS2000(FILE-NAME= -

/ C‘|ftinfo -csv‘, -

/ TRANSFER-ADMISSION=PROFUNKNOWN)
% FTR0000 Auftrag 132274 angenommen

Kurzform:

/TFF FR,UNKNOWN,(FTINFO.UNKNOWN),('|ftinfo -csv',,PROFUNKNOWN)

Lokale Vor- und ferne Nachverarbeitung:
Es soll die Information über die letzen 100 lokal geschriebenen Logging-Sätze im fernen BS2000-System PARTBS2 in der Datei FILE.LOG unter der
Zugangsberechtigung TRANSADM abgelegt werden. Die Datei FILE.LOG soll nach der Übertragung nicht überschreibbar sein.
/TFF TO,PARTBS2,('|/SH-FT-LOG ,100,OUT=*SYSLST'),                -
/       ('|/CPF %TEMPFILE,FILE.LOG;/MDFA FILE.LOG,PROT=(,*READ)' -
/       ,,TRANSADM)

Your Browser is not longer supported

Please use Google Chrome, Mozilla Firefox or Microsoft Edge to view the page correctly

Beispiele zum TRANSFER-FILE-Kommando