Kopieren von Elementen

Elemente aus unterschiedlichen Bibliotheken werden in eine Bibliothek kopiert.

/add-file-link link-name=lib1,file-name=modul.lib  -----------------------  (1) 

/start-lms ---------------------------------------------------------------  (2)

//modify-logging-parameters logging=*maximum -----------------------------  (3)

//open-library library=bsp2.bib,mode=*update -----------------------------  (4)

LIBRARY IS CLEARED AND PREPARED

//show-element-attributes (library=*link(link-name=lib1),type=r) ---------  (5)

INPUT  LIBRARY= :1OSN:$USER.MODUL.LIB,LINK=LIB1
TYP NAME   VER (VAR#) DATE
(R) MODERF @   (0001) 2013-03-01
      1 (R)-ELEMENT(S) IN THIS TABLE OF CONTENTS

//copy-element elem=(library=*link(link-name=lib1),elem=moderf,type=r), -

//           to-element=(library=*std,element=mod.erf) -------------------  (6)

INPUT  LIBRARY= :1OSN:$USER.MODUL.LIB,LINK=LIB1
OUTPUT LIBRARY= :1OSN:$USER.BSP2.BIB

        COPY (R)MODERF/@(0001)/2011-02-19 AS (R)MOD.ERF/@(0001)/2011-02-19

(1)	Dadurch kann während des LMS-Laufs die Bibliothek MODUL.LIB über den Dateikettungsnamen LIB1 zugewiesen werden.
(2)	LMS wird aufgerufen.
(3)	Zusätzlich zu Fehlermeldungen werden auch Erfolgsmeldungen protokolliert.
(4)	Die Bibliothek BSP2.BIB wird als globale Bibliothek neu eingerichtet und zum Schreiben und Lesen eröffnet.
(5)	Das Inhaltsverzeichnis der Bibliothek MODUL.LIB, die über den Dateikettungsnamen LIB1 angegeben wird, soll aufgelistet werden.
(6)	Der Modul MODERF aus der Bibliothek MODUL.LIB wird in die Bibliothek BSP2.BIB mit dem Elementnamen MOD.ERF kopiert.

//show-element-attributes (library=macro.lib,type=m) -------------------   (7) 

INPUT  LIBRARY= :1OSN:$USER.MACRO.LIB
TYP NAME VER (VAR#) DATE        NAME VER (VAR#) DATE
(M) MAC1 @   (0001) 2011-02-19 MAC2 @   (0001) 2011-02-19
      2 (M)-ELEMENT(S) IN THIS TABLE OF CONTENTS

//copy-element elem=(library=macro.lib,elem=mac*,type=m), -
//           to-element=(library=*std,element=mu*) ---------------------   (8)

INPUT  LIBRARY= :1OSN:$USER.MACRO.LIB
OUTPUT LIBRARY= :1OSN:$USER.BSP2.BIB

        COPY (M)MAC1/@(0001)/2011-02-19 AS (M)MU1/@(0001)/2011-02-19
        COPY (M)MAC2/@(0001)/2011-02-19 AS (M)MU2/@(0001)/2011-02-19 ---   (9)

//show-element-attributes (library=quell.lib,type=s) -------------------  (10)

INPUT  LIBRARY= :1OSN:$USER.QUELL.LIB
TYP NAME    VER (VAR#) DATE        NAME    VER (VAR#) DATE
(S) EDTB    @   (0001) 2011-02-19   PROT    @   (0001) 2011-02-19
(S) SEINAUS @   (0001) 2011-02-19   SERFAS  @   (0001) 2011-02-19
      4 (S)-ELEMENT(S) IN THIS TABLE OF CONTENTS

//copy-element elem=(library=quell.lib,elem=*,type=s, -
//                 except-element=(element=edtb)) ----------------------  (11)

INPUT  LIBRARY= :1OSN:$USER.QUELL.LIB
OUTPUT LIBRARY= :1OSN:$USER.BSP2.BIB

        COPY (S)PROT/@(0001)/2011-02-19 AS (S)PROT/@(0001)/2011-02-19
        COPY (S)SEINAUS/@(0001)/2011-02-19 AS (S)SEINAUS/@(0001)/2011-02-19
        COPY (S)SERFAS/@(0001)/2011-02-19 AS (S)SERFAS/@(0001)/2011-02-19

(7)	Das Inhaltsverzeichnis der Bibliothek MACRO.LIB, die als lokale Bibliothek zugewiesen wird, soll aufgelistet werden.
(8)	Diejenigen Elemente der Bibliothek MACRO.LIB werden in die Bibliothek BSP2.BIB kopiert, deren Elementbezeichnung mit "MAC" beginnt. Die neuen Elementbezeichnungen beginnen mit "MU". Ab der dritten Stelle werden die Elementbezeichnungen der Eingabeelemente übernommen.
(9)	Erfolgsmeldung: Die ausgewählten Elemente wurden mit den neuen Elementbezeichnungen kopiert.
(10)	Das Inhaltsverzeichnis der Bibliothek QUELL.LIB, die als lokale Bibliothek zugewiesen wird, soll aufgelistet werden.
(11)	Alle Elemente der Bibliothek QUELL.LIB mit Ausnahme des Elementes EDTB werden in die Ausgabebibliothek kopiert.

//show-element-attributes (library=test.lib) ----------------------------- (12) 

INPUT  LIBRARY= :1OSN:$USER.TEST.LIB
TYP NAME   VER (VAR#) DATE
(S) SERFAS @   (0001) 2011-02-19
      1 (S)-ELEMENT(S) IN THIS TABLE OF CONTENTS

//copy-element elem=(library=test.lib,elem=*,type=*), -
//           to-elem=(library=*std,element=*(version=007)) --------------- (13)

INPUT  LIBRARY= :1OSN:$USER.TEST.LIB
OUTPUT LIBRARY= :1OSN:$USER.BSP2.BIB

        COPY (S)SERFAS/@(0001)/2011-02-19 AS (S)SERFAS/007(0001)/2011-02-19

(12)	Das Inhaltsverzeichnis der Programmbibliothek TEST.LIB, die als lokale Bibliothek zugewiesen wird, soll aufgelistet werden.
(13)	Alle Elemente der Programmbibliothek TEST.LIB werden in die Ausgabebibliothek kopiert und dort unter ihrem Namen und der Versionsnummer 007 abgelegt.

//show-element-attributes ------------------------------------------------ (14)    

INPUT  LIBRARY= :1OSN:$USER.BSP2.BIB

TYP NAME VER (VAR#) DATE        NAME VER (VAR#) DATE

(M) MU1  @   (0001) 2011-02-19   MU2  @   (0001) 2011-02-19

      2 (M)-ELEMENT(S) IN THIS TABLE OF CONTENTS

TYP NAME    VER (VAR#) DATE

(R) MOD.ERF @   (0001) 2011-02-19

      1 (R)-ELEMENT(S) IN THIS TABLE OF CONTENTS

TYP NAME    VER (VAR#) DATE        NAME    VER (VAR#) DATE

(S) PROT    @   (0001) 2011-02-19   SEINAUS @   (0001) 2011-02-19

(S) SERFAS  007 (0001) 2011-02-19   SERFAS  @   (0001) 2011-02-19

      4 (S)-ELEMENT(S) IN THIS TABLE OF CONTENTS

-------------------------------------------------------------------------------

      7 ELEMENT(S) IN THIS TABLE OF CONTENTS

//show-library-status ---------------------------------------------------  (15)

STATUS FILENAME                                          MODE    LINK     DEF-TYPE

CLOSED :1OSN:$USER.TEST.LIB

CLOSED :1OSN:$USER.QUELL.LIB

CLOSED :1OSN:$USER.MACRO.LIB

CLOSED :1OSN:$USER.MODUL.LIB                                      LIB1

OPEN   :1OSN:$USER.BSP2.BIB                               UPDATE

//close-library ---------------------------------------------------------  (16)

//show-library-status ---------------------------------------------------  (17)

STATUS FILENAME                                          MODE    LINK     DEF-TYPE

CLOSED :1OSN:$USER.TEST.LIB

CLOSED :1OSN:$USER.QUELL.LIB

CLOSED :1OSN:$USER.MACRO.LIB

CLOSED :1OSN:$USER.MODUL.LIB                                      LIB1

CLOSED :1OSN:$USER.BSP2.BIB

//end -------------------------------------------------------------------  (18)

(14)	Das Inhaltsverzeichns der aktuellen Eingabebibliothek BSP2.BIB soll mit allen Elementen aufgelistet werden. Es existieren 2 Elemente mit dem Elementnamen SERFAS mit unterschiedlicher Versionsnummer.
(15)	Der Zustand der im LMS-Lauf verwendeten Bibliotheken wird abgefragt.
(16)	Die Bibliothek BSP2.BIB wird geschlossen.
(17)	Der Zustand der im LMS-Lauf verwendeten Bibliotheken wird abgefragt.
(18)	Der LMS-Lauf wird beendet.